Arkadaşlar ben deniz ticaret sistemi yazıyorum ve vendorda target yapamadığım için item kullandım

[itemdef i_deniz_ticaret_1]

id i_deed

name Balik kontrati

weight 1



on=@create

color 57



on=@click

message @1153,,1 [ Deniz ticaret belgesi ]

message @1996,,1 Pişmiş balık kontratı

message @043,,1 <eval <tag0.pbalik>> Pişmiş balık

return 1



on=@DClick

if (<tag0.pbalik> == 5)

src.sysmessage @1153,,1 Kontrat dolu! Lütfen deed'i istenen vendora teslim ediniz.

src.dialog d_belge_doldu

return 1

endif

src.sysmessage @1996,,1 Pişmiş balıklar nerede?

target

return 1



on=@targon_item

if (<tag0.pbalik> == 5)

src.sysmessage @1153,,1 Kontrat dolu! Lütfen deed'i istenen vendora teslim ediniz.

src.dialog d_belge_doldu

return 1

endif

if (<src.targ.baseid> == i_fish_cut_cooked)

src.targ.remove

tag0.pbalik ++ <<>> Bilmiyorum ama amount koymadığım için olabilir.

src.sysmessage @1996,,1 Pişirilen balıklar ticaret belgenize eklenmiştir..

return 1

else

src.sysmessage @021,,1 Sadece pişirilen balıklar bu kontrata atılabilir!

return 1

endif

Burada bir hata var, ben 2 3 veya 10 pişmiş balık eklersem kontrata gene + 1 balık ekleniyor
Burada ise target ta örnek olarak 5 pbalik - dbalik yapmıştım ama kontratta balık miktarını aramıyor.

on=@targon_item

if (<src.targ.baseid> == i_deniz_ticaret_1) && (<tag0.pbalik> == 5)

src.sysmessage @1153,,1 Dolu balık kontratını teslim ettiğiniz için çantanıza 500 K çek düşmüştür, iyi oyunlar..

src.findid.i_deniz_ticaret_1.remove

src.newitem i_gold == 65000	// Örnek

src.act.bounce

return 1

else

if (<src.targ.baseid> == i_deniz_ticaret_2) && (<tag0.dbalik> == 5)

src.sysmessage @1153,,1 Dolu balık kontratını teslim ettiğiniz için çantanıza 500 K çek düşmüştür, iyi oyunlar..

src.findid.i_deniz_ticaret_2.remove

src.newitem i_gold == 65000	// Örnek

src.act.bounce

return 1

else

src.sysmessage @021,,1 Sadece dolu balık kontratlarını seçebilirsin <src.name>!

return 1

endif



ON=@TARGON_CHAR

src.sysmessage @021,,1 Sadece Balık ticaret kontratını seç!

return 1

Mesela şöyle denemiştim ilk başta:
Buradaki && (<tag0.pbalik> == 5) kaldırılırsa " i_deniz_ticaret_1 veya i_deniz_ticaret_2 " yi silip para veriyor..
Bu arada

[EVENTS e_pbalik]

tag.pbalik 0

src.targ.remove

Birinci olarak burada sorun şu ki, 5 balık alan bir kontrata 10 balık eklemeye çalışsan 10'unu da siliyor, yani direkt olarak itemi silmek yerine önce miktarı hesaplayıp eğer itemin miktarı fazlaysa amountu azaltmak gerekir.

tag0.pbalik ++ <<>> Bilmiyorum ama amount koymadığım için olabilir.

Burada tahmin ettiğin gibi sorun amount girmemen, ++ demek +1 demektir yani +=1, yani sen kontratın balık miktarını miktara göre değil ne olursa olsun 1 arttır diye ayarlamışsın. Yine üstteki ile aynı sebepten kaynaklı olarak öncelikle tıklanan balık miktarını alıp, pbalık tagına ekleyip, çıkan değer eğer maksimum alacağı miktardan fazla ise, aradaki farkı hesaplayıp, balıktan alınacak kısımdan bu miktar çıkarılıp geri kalan değer -amount yapılıp kontrata ise tag0.pbalık += miktar şeklinde tanımlanmalı.

if (<src.targ.baseid> == i_deniz_ticaret_1) && (<tag0.pbalik> == 5)

if (<src.targ.baseid> == i_deniz_ticaret_2) && (<tag0.dbalik> == 5)

Bu ikisinde de sorun sabit, "ticaret kağıdının" uidi "I" yani <UID> değil, yani tag0.dbalık yaparak hesaplatamazsın, bu durumda SRC.TARG.TAG0.pbalik şeklinde olmalıydı. Diğer yandan i_deniz_ticaret_2 deki tagın adı pbalik değil dbalik yazılmış, hatalı mı öyle mi incelemedim.

Hocam çok teşekkür ederim ama dediğin gibi atıyorum elinde 8 balık varsa kontrata hepsini ekliyor, 5 balık eklemesini ve -amount kısmını anlamadım
Yani anlatmak istediğim -amount'u tanımlamadım..
Evet dediğin gibi olmalı ama ben -amount nasıl eklerim, bir bilgim yok..

insaların işlerini kolaylaştırmak yerine zorlaştırmak daha mantıklı tek tek eklesinler bu şekilde

[itemdef i_deniz_ticaret_1]

id i_deed

name Balik kontrati

weight 1



on=@create

color 57



on=@click

message @1153,,1 [ Deniz ticaret belgesi ]

message @1996,,1 Pişmiş balık kontratı

message @043,,1 <eval <tag0.pbalik>> Pişmiş balık

return 1



on=@DClick

if (<tag0.pbalik> == 5)

src.sysmessage @1153,,1 Kontrat dolu! Lütfen deed'i istenen vendora teslim ediniz.

src.dialog d_belge_doldu

return 1

endif

src.sysmessage @1996,,1 Pişmiş balıklar nerede?

target

return 1



on=@targon_item

REF1=<uid>

if (<tag0.pbalik> == 5)

src.sysmessage @1153,,1 Kontrat dolu! Lütfen deed'i istenen vendora teslim ediniz.

src.dialog d_belge_doldu

return 1

endif

if (<src.targ.baseid> == i_fish_cut_cooked)

src.consume 1 i_fish_cut_cooked

REF1.tag0.pbalik +=1  //  Bilmiyorum ama amount koymadığım için olabilir.

target

src.sysmessage @1996,,1 Pişirilen balıklar ticaret belgenize eklenmiştir..

return 1

else

src.sysmessage @021,,1 Sadece pişirilen balıklar bu kontrata atılabilir!

return 1

endif

Dediğini yaparsan serwerda oynayan olmaz
Sen burada " REF1=<UID> yazmızsın, ne işe yaradığını bilmiyorum ama ben bu şekilde sorunsuz kullanıyorum -amount hariç

on=@click

message @1153,,1 [ Deniz ticaret belgesi ]

message @1996,,1 Pişmiş balık kontratı

message @043,,1 <eval <tag0.pbalik>> Pişmiş balık

return 1



on=@DClick

if !(<cont> == <src.findlayer.21.uid>)

src.sysmessage @021,,1 Bunu kullanabilmeniz için çantanızda olması gerekmektedir.

return 1

endif

if (<tag0.pbalik> == 5) <<>>Burada kontrat 5 balık ise çift tıklamayı engelledim zaten ama target önemli

src.sysmessage @1153,,1 Kontrat dolu! Lütfen deed'i istenen vendora teslim ediniz.

src.dialog d_belge_doldu

return 1

endif

src.sysmessage @1996,,1 Pişmiş balıklar nerede?

target

return 1



on=@targon_item

if (<src.targ.baseid> == i_fish_cut_cooked)

src.targ.remove

tag0.pbalik += <src.targ.amount>

src.sysmessage @1996,,1 Pişirilen balıklar ticaret belgenize eklenmiştir..

return 1

else

src.sysmessage @021,,1 Sadece pişirilen balıklar bu kontrata atılabilir!

return 1

endif

Işte burada dediğim gibi, kontrata 5'den fazla eklemesin
Örneğin;
8 tane tageta seçtiği zaman deed'da 1 balık varsa 4'ü deed'a ekleyip, 4'ünü çantasına atsın

manyaqq :
Hocam çok teşekkür ederim ama dediğin gibi atıyorum elinde 8 balık varsa kontrata hepsini ekliyor, 5 balık eklemesini ve -amount kısmını anlamadım
Yani anlatmak istediğim -amount'u tanımlamadım..
Evet dediğin gibi olmalı ama ben -amount nasıl eklerim, bir bilgim yok..

Şimdi şöyle açıklayayım, atıyorum ki 10 balık var ve kontratta 1 balık var, sen ise kontratta maksimum 5 balık olmasını istiyorsun, bu durumda yapman gereken nedir, 10 balıktan 4 ünü alıp kontrata eklemek, işte bunu sağlamak içinse

-> (kontratın alacağı maksimum balık miktarı - kontrattaki balık miktarı) değerini hesaplamak ve eğer eklenen balık stackinde bu değerden fazla balık var ise ki bu durumda "10", 10 dan yukardaki işlemin sonucunu çıkarmak ki bu durumda "4", yani sonuç olarak stack sayısını 10 dan 6 ya düşürmek ve kontrata 4 balık eklemek.

On=@TargOn_Item

IF (<tag0.pbalik> == 5)

  src.sysmessage @1153,,1 Kontrat dolu! Lütfen deed'i istenen vendora teslim ediniz.

  src.dialog d_belge_doldu

ELIF (<src.targ.baseid> == i_fish_cut_cooked)

  //Burada SRC.TARG.REMOVE yapmamız doğru değil çünkü eklenecek balık miktarı, stack sayısından az olabilir.

  LOCAL.MAX = <EVAL 5 - <dTAG0.pbalik>> //Burada kontratın maksimum 5 balık alacağını ve bu 5 balıktan kontratta bulunan balık sayısını çıkarttık.

  IF (<SRC.TARG.AMOUNT> > <dLOCAL.MAX>) //Eğer stacktaki balık sayısı kontrata eklenecekten fazla ise;

    SRC.TARG.AMOUNT -= <dLOCAL.MAX> //Stacktaki balık sayısını eklenebilecek maksimum değer kadar azalt.

  ELSE //Eğer stacktaki balık sayısı kontrata eklenecekten az veya eşit ise;

    LOCAL.MAX = <SRC.TARG.AMOUNT> //Maksimum balık miktarını stack sayısı ile eşitle.

    SRC.TARG.REMOVE //Balıkları sil.

  ENDIF

  tag0.pbalik += <dLOCAL.MAX> //Belirlenen maksimum değer kadar balık ekle.

  src.sysmessage @1996,,1 Pişirilen <dLOCAL.MAX> balık ticaret belgenize eklenmiştir..

ELSE

  src.sysmessage @021,,1 Sadece pişirilen balıklar bu kontrata atılabilir!

ENDIF

RETURN 1

Hocam çok teşekkür ederim.

Sen önce hele bir server açta Sonrasinana oyunuyup oynamıyacagına playerlar karar verir @manyaqq
2 src 1 act ile olmaz bu işler al sana istedigin sistem

[FUNCTION ADD_BALIK]

IF !(<SRC.RESCOUNT I_FISH_CUT_COOKED>) /// bu sorguyuda yapalimda adamlar bug yapmasın.

  SRC.SYSMESSAGE @33,1,1 Pişmiş balıklar çantanızda olmalı 

  RETURN 1

ENDIF

SRC.SYSMESSAGE @07a1,1,1 <Src.rescount i_fish_cut_cooked> Adet Balik Eklediniz

LOCAL.ADET=<Src.rescount i_fish_cut_cooked>

WHILE <LOCAL.ADET>



IF (<LOCAL.ADET> >= 5)

SERV.NEWITEM i_deniz_ticaret_1

NEW.TAG0.PBALIK =5

SRC.CONSUME 5 i_fish_cut_cooked

LOCAL.ADET -= 5

ELSE

SERV.NEWITEM i_deniz_ticaret_1

NEW.TAG0.PBALIK =<LOCAL.ADET>

SRC.CONSUME <LOCAL.ADET> i_fish_cut_cooked

LOCAL.AMOUNT=0

ENDIF



IF (0<ARGN2>)

NEW.CONT <ARGN2>

ELSE

BOUNCE <NEW>

ENDIF

ENDWHILE







[itemdef i_deniz_ticaret_1]

id i_deed

name Balik kontrati

weight 1



on=@create

color 57



on=@click

message @1153,,1 [ Deniz ticaret belgesi ]

message @1996,,1 Pişmiş balık kontratı

message @043,,1 <eval <tag0.pbalik>> Pişmiş balık

return 1



on=@DClick

if (<tag0.pbalik> == 5)

src.sysmessage @1153,,1 Kontrat dolu! Lütfen deed'i istenen vendora teslim ediniz.

src.dialog d_belge_doldu

return 1

endif

src.sysmessage @1996,,1 Pişmiş balıklar nerede?

target

return 1



on=@targon_item

REF1=<uid>

if (<tag0.pbalik> == 5)

src.sysmessage @1153,,1 Kontrat dolu! Lütfen deed'i istenen vendora teslim ediniz.

src.dialog d_belge_doldu

return 1

endif

if (<src.targ.baseid> == i_fish_cut_cooked) && (<SRC.RESCOUNT I_FISH_CUT_COOKED>)

REF1.REMOVE

src.add_balik

src.sysmessage @1996,,1 Pişirilen balıklar ticaret belgenize eklenmiştir..

return 1

else

src.sysmessage @021,,1 Sadece pişirilen balıklar bu kontrata atılabilir!

return 1

endif

ama hocam herkes kolaydan öğrenmeye başlar değil mi?