Muhtemelen arkadaş bir iteme timer vererek yapmıştır timer bitince tag.xx +=10 ve timer 10 şeklinde döngüye sokmuş olabilir tabi konu başlığı biraz sipariş script gibi olmuş

öncelikle ilginiz için teşekkür ederim.

Benim demek istediğim; burda süre felan yok örnegin kumbara misali kumbaraya ne kadar para yüklerseniz o kadar para çekebilirsiniz çek halinde benimde demek istediğim oyunda aktif olğumuz sürece içerisinde karaktere kredi geliyor bu kredileride deed haline çevirebilmek istiyorum.

kred tag: tag0.puanverkredi

Güle güle kullan

.kredicevir yazman yeterli.

[itemdef i_deed_krediver]

id i_deed

type t_script

name Kredi deed



on=@create

color 052d

attr 04



on=@click

message @33,,1 [<eval <tag0.puanverkredi>>]

message @33,,1 Kredi Deed

return 1



on=@dclick

if !(<cont.uid> == <src.findlayer.21.uid>)

src.sysmessage @33,,1 deed'i sadece çantanızda kullanabilirsiniz.

return 1

endif



src.tag.puanverkredi += <dtag.puanverkredi>

src.sysmessage @33,,1 <eval <tag.puanverkredi>> adet kredi hesabınıza eklenmiştir.

remove

return 1



[plevel 1]

kredicevir



[function kredicevir]

sdialog d_krediver



[dialog d_krediver]

0,35

resizepic 0 0 5120 470 120

resizepic 10 10 3000 450 100

resizepic 20 35 3000 440 2

dhtmlgump 170 15 300 30 0 0 <def.BFONT_dRED> <serv.name> - Kredi Çevirme

dhtmlgump 20 80 150 20 0 0 <def.bfont_dred>Şuanki Kredi : <def.bfont_dgreen> <dtag.puanverkredi>



resizepic 105 50 3000 65 17

dtextentry 110 49 55 20 0 1

dhtmlgump 20 50 110 20 0 0 <def.bfont_red>Kredi Çevir :

button 300 50 4023 4025 1 0 1

dhtmlgump 200 50 110 20 0 0 <def.bfont_dgreen>İşlemi Tamamla 



[dialog d_krediver Button]

on=0

src.sysmessage @33,,1 Vazgeçtiniz.



on=1

if !(<isnum <argtxt[1]>>)

src.sysmessage Rakam girmelisiniz.

sdialog d_krediver

return 1

endif

if (<eval <src.tag.puanverkredi>> < <eval <argtxt[1]>>)

src.sysmessage @33,,1 Bu kadar krediniz yok.

sdialog d_krediver

return 1

endif

if (<eval <argtxt[1]>> <100)

src.sysmessage @33,,1 En az 100 krediyi Deed yapabilirsiniz.

sdialog d_krediver

return 1

endif

if (<eval <argtxt[1]>> > 50000)

src.sysmessage @33,,1 En çok 50000 krediyi Deed yapabilirsiniz.

sdialog d_krediver

return 1

endif

src.tag.puanverkredi -= <eval <argtxt[1]>>

serv.newitem i_deed_krediver

new.tag.puanverkredi <eval <argtxt[1]>>

new.bounce

src.sysmessage @33,,1 Kredilerinizi deede çevirdiniz.



[eof]

Allah razı olsun eline koluna sağlık reis xrambo