|
|
/
// FUNCTIONS
[FUNCTION ispatriarch]
DB.QUERY "SELECT patriarch FROM families WHERE name='<surname>'"
if <db.row.numrows>
if <db.row.0> == <uid>
return 1
endif
endif
return 0
[FUNCTION surname]
DB.QUERY "SELECT family FROM chars WHERE uid='<uid>'"
if <db.row.numrows>
return <db.row.0>
endif
return
[FUNCTION spouse]
DB.QUERY "SELECT spouse FROM chars WHERE uid='<uid>'"
if <db.row.numrows>
ref1 = <db.row.0>
return <ref1>
endif
return 0
[function ismale]
if (<body> == c_gargoyle_male) || (<body> == c_elf_male) || (<body> == c_man)
return 1
endif
return 0
[function isfemale]
if (<body> == c_gargoyle_female) || (<body> == c_elf_female) || (<body> == c_woman)
return 1
endif
return 0
[FUNCTION HuePicker] // SaCi_Br
ref1 = <args>
SRC.SENDPACKET 095 d<ARGS> w<ref1.id> W<ref1.color>
SRC.CTAG.HUEPICKER=<ARGS>
[FUNCTION f_hue_picker]
REF1=<LOCAL.CHAR>
DB.QUERY "SELECT * FROM families WHERE ring_hue='<LOCAL.7><STRSUB 1 0 <LOCAL.8>>'"
if <db.row.numrows>
ref1.sysmessage @,,1 Bu renk başka bir aile tarafından kullanıldığı için kullanılamaz.
return 1
endif
IF (<REF1.CTAG0.HUEPICKER>)
UID.<REF1.CTAG0.HUEPICKER>.COLOR=<LOCAL.7><STRSUB 1 0 <LOCAL.8>>
REF1.CTAG.HUEPICKER=
DB.EXECUTE "UPDATE families SET ring_hue='<LOCAL.7><STRSUB 1 0 <LOCAL.8>>'"
DB.QUERY "SELECT * FROM chars WHERE family='<ref1.surname>'"
if <db.row.numrows>
for 0 <eval (<db.row.numrows> - 1)>
ref2 = <db.row.<dlocal._for>.uid>
ref2.findid(i_ring_family).color = <LOCAL.7><STRSUB 1 0 <LOCAL.8>>
endif
endif
ENDIF
////////////////////////////
// ITEMS
[ITEMDEF i_deed_marriage]
ID=i_deed
TYPE=t_script
NAME=evlilik belgesi
VALUE=15000
on=@DClick
if <topobj> != <src>
src.sysmessage @,,1 Üzerinizde olmayan eşyaları kullanamazsınız.
return 1
endif
if <src.spouse>
src.sysmessage @,,1 Zaten evlisiniz.
return 1
endif
if <src.isfemale>
src.sysmessage @,,1 Aile liderleri erkek olmak zorundadır.
return 1
endif
if <src.isevent.e_proposal>
src.sysmessage @,,1 BaÅŸka birine evlenme teklifi etmiÅŸsiniz. Teklifinize cevap alana kadar bekleyin.
return 1
endif
target @,,1 Evlenmek istediğiniz kişiyi seçin.
return 1
on=@TargOn_Char
if <src.targ.npc>
return 1
elif !<src.targ.isonline>
return 1
endif
if !<src.targ.isfemale>
src.sysmessage @,,1 Bu karaktere evlenme teklifi edemezsiniz.
return 1
endif
if <src.targ.spouse>
src.sysmessage @,,1 <src.targ.name> zaten evli.
return 1
endif
if <src.targ.isevent.e_proposal>
src.sysmessage @,,1 BaÅŸka biri bu kiÅŸiye evlenme teklifi etmiÅŸ. <src.targ.name> teklife cevap verene kadar bekleyin.
return 1
endif
src.targ.ctag.proposer = <src>
src.ctag.proposedto = <src.targ>
src.events +e_proposal
src.targ.events +e_proposal
trysrc <src.targ> sdialog d_proposal_window
return 1
[ITEMDEF i_ring_family]
ID=i_ring_gold
NAME=aile yüzüğü
ON=@Create
attr |= attr_newbie
ON=@DClick
src.sdialog d_family
ON=@DropOn_Ground
bounce
return 1
ON=@DropOn_Char
return 1
ON=@DropOn_Item
if <argo> != <src.findlayer(layer_pack).uid>
return 1
endif
////////////////////////////
// EVENTS
[EVENTS e_proposal]
on=@Logout
if <ctag0.proposer>
ref1 = <ctag.proposer>
ref1.sysmessage @,,1 <name> teklifinizi reddetti.
ref1.dialogclose d_family_name
ref1.events -e_proposal
events -e_proposal
elif <ctag0.proposedto>
ref1 = <ctag.proposedto>
ref1.sysmessage @,,1 <name> teklifinden vazgeçti.
ref1.dialogclose d_proposal_window
ref1.events -e_proposal
events -e_proposal
endif
////////////////////////////
// DIALOGS - PROPOSAL
[DIALOG d_proposal_window]
200,200
noclose
page 0
resizepic 0 0 5054 400 140
gumppictiled 10 10 380 120 2624
checkertrans 10 10 380 120
ref1 = <src.ctag.proposer>
dhtmlgump 20 20 360 70 1 0 <ref1.name> size evlenme teklifi etti. <qval (<isempty <ref1.surname>>) ? Onunla bir aile kurmak istiyor musunuz?:<ref1.surname> ailesine katılmak istiyor musunuz? Siz kabul ettikten sonra evliliğin aile reisi tarafından onaylanması gerekmektedir.>
button 50 100 4005 4006 1 0 1
dtext 85 102 1153 Evet
button 250 100 4005 4006 1 0 0
dtext 285 102 1153 Hayır
[DIALOG d_proposal_window BUTTON]
ON=0
ref1 = <src.ctag.proposer>
ref1.sysmessage @,,1 <src.name> teklifinizi reddetti.
ref1.events -e_proposal
src.events -e_proposal
ON=1
ref1 = <src.ctag.proposer>
if <isempty <ref1.surname>>
trysrc <ref1> sdialog d_family_name
else
DB.EXECUTE "INSERT INTO chars VALUES ('<src>','<src.name>','<ref1.surname>','<ref1>',0) ON DUPLICATE KEY UPDATE family='<ref1.surname>', spouse='<ref1>', fullmember=0"
DB.EXECUTE "UPDATE chars SET spouse='<src>' WHERE uid='<ref1>'"
ref1.sysmessage @,,1 <src.name> teklifinizi kabul etti. Aile reisinizin evliliği onaylaması gerekli.
src.sysmessage @,,1 <ref1.surname> aile reisi onayladıktan sonra evliliğiniz geçerlilik kazanacaktır.
remove
endif
ref1.events -e_proposal
src.events -e_proposal
[DIALOG d_family_name]
200,200
noclose
page 0
resizepic 0 0 5054 400 140
gumppictiled 10 10 380 120 2624
checkertrans 10 10 380 120
ref1 = <src.ctag.proposedto>
dhtmlgump 20 20 360 40 1 0 <ref1.name> teklifinizi kabul etti. Aileniz için bir soyadı belirleyin.
resizepic 30 70 3000 340 20
dtextentrylimited 34 70 340 20 1153 0 20
button 50 100 4005 4006 1 0 1
dtext 85 102 1153 Devam
button 250 100 4005 4006 1 0 0
dtext 285 102 1153 Vazgeç
[DIALOG d_family_name BUTTON]
ON=1
if !strmatch(*[A-Za-z]*,<argtxt[0]>)
src.sysmessage @,,1 Soyadınızda sadece harf kullanabilirsiniz.
return 1
endif
if strlen(<argtxt[0]>) < 4
src.sysmessage @,,1 Soyadınız en az 4 karakter olmak zorunda.
return 1
endif
DB.QUERY "SELECT * FROM families WHERE name='<argtxt[0]>'"
if <db.row.numrows>
src.sysmessage @,,1 Bu isim zaten kullanımda.
return 1
endif
ref1=<src.ctag.proposedto>
DB.EXECUTE "INSERT INTO families VALUES (NULL,'<argtxt[0]>','<src>',0)"
DB.EXECUTE "INSERT INTO chars VALUES ('<src>','<src.name>','<argtxt[0]>','<ref1>',1) ON DUPLICATE KEY UPDATE family='<argtxt[0]>', spouse='<ref1>', fullmember=1"
DB.EXECUTE "INSERT INTO chars VALUES ('<ref1>','<ref1.name>','<argtxt[0]>','<src>',1) ON DUPLICATE KEY UPDATE family='<argtxt[0]>', spouse='<src>', fullmember=1"
serv.newitem i_ring_family,1,<src>,1
serv.newitem i_ring_family,1,<ref1>,1
serv.b @,,1 <src.name> ve <ref1.name> <argtxt[0]>'a mutluluklar dileriz.
src.tag.name.suffix = " <argtxt[0]>"
ref1.tag.name.suffix = " <argtxt[0]>"
src.events -e_proposal
ref1.events -e_proposal
remove
////////////////////////////
// DIALOGS - MAIN
[DIALOG d_family]
70,100
page 0
resizepic 0 0 5054 650 340
gumppictiled 10 10 500 320 2624
checkertrans 10 10 500 320
// right
gumppictiled 515 10 125 320 2624
checkertrans 515 10 125 320
if <ispatriarch>
DB.QUERY "SELECT * FROM chars WHERE family='<surname>' AND fullmember=0"
local.pending_marriage = <db.row.numrows>
dtext 530 17 <qval (<local.pending_marriage>) ? 1153:33> Onaylar <qval (<local.pending_marriage>) ? (<dlocal.pending_marriage>):>
button 610 20 04b9 04ba <qval (<local.pending_marriage>) ? 1:0> 0 1
dtext 530 37 1153 Ãœye Al
button 610 40 04b9 04ba 1 0 2
dtext 530 57 1153 Yüzük Rengi
button 610 60 04b9 04ba 1 0 3
dtext 530 77 1153 Aileyi Yık
button 610 80 04b9 04ba 1 0 4
if <spouse>
dtext 530 97 1153 BoÅŸan
button 610 100 04b9 04ba 1 0 6
endif
else
dtext 530 17 1153 Aileden Ayrıl
button 610 20 04b9 04ba 1 0 5
if <ismale> && <spouse>
dtext 530 37 1153 BoÅŸan
button 610 40 04b9 04ba 1 0 6
endif
endif
// center
dhtmlgump 10 20 500 20 0 0 <def.center><def.bfont_white><surname> Ailesi
DB.QUERY "SELECT * FROM chars WHERE family='<surname>' AND fullmember=1 AND spouse!=0"
local.lines = <eval (<db.row.numrows> / 2)>
DB.QUERY "SELECT * FROM chars WHERE family='<surname>' AND fullmember=1 AND spouse=0"
local.lines += <db.row.numrows>
local.page = 1
page 1
local.y = 60
DB.QUERY "SELECT * FROM chars WHERE family='<surname>'"
for 0 <eval (<db.row.numrows> - 1)>
ref1 = <db.row.<dlocal._for>.uid>
if !<local.<ref1>>
ref2 = <db.row.<dlocal._for>.spouse>
if (<ref2> && <ref1.ismale>) || !(<ref2>)
button 35 <eval (<local.y> + 3)> 04b9 04ba 1 0 <eval (100 + <ref1>)>
dtext 55 <local.y> <qval (<ref1.ismale>) ? 0122 ♂:0e6 ♀>
dtext 70 <local.y> <qval (<ref1.isonline>) ? 03e:33> <ref1.name>
local.<ref1> = 1
if <ref2>
button 265 <eval (<local.y> + 3)> 04b9 04ba 1 0 <eval (100 + <ref2>)>
dtext 285 <local.y> 0e6 ♀
dtext 300 <local.y> <qval (<ref2.isonline>) ? 03e:33> <ref2.name>
local.<ref2> = 1
endif
local.y += 30
local.line ++
if (<eval (<local.line> % 8)> == 0) && (<local.line> < <local.lines>)
local.page ++
button 100 20 4005 4006 0 <dlocal.page> 0
page <dlocal.page>
local.y = 60
button 20 20 4014 4015 0 <eval (<local.page> - 1)> 0
endif
endif
endif
endfor
[DIALOG d_family BUTTON]
ON=1
sdialog d_family_confirmation
ON=2
targetf uyeal
sysmessage @,,1 Ailenize dahil etmek istediğiniz kişiyi seçin.
ON=3
huepicker <findid(i_ring_family).uid>
ON=4
sdialog d_family_demolish
ON=5
sdialog d_family_leave
ON=6
sdialog d_family_divorce
ON=100 50000000
ref1=<hval (<argn1> - 100)>
ctag.family.member = <ref1>
sdialog d_family_member
[DIALOG d_family_confirmation]
70,100
page 0
resizepic 0 0 5054 520 340
gumppictiled 10 10 500 320 2624
checkertrans 10 10 500 320
dhtmlgump 10 20 500 20 0 0 <def.center><def.bfont_white><surname> Ailesi
local.page = 1
page 1
local.y = 60
DB.QUERY "SELECT * FROM chars WHERE family='<surname>' AND fullmember=0"
if <db.row.numrows>
for 0 <eval (<db.row.numrows> - 1)>
ref1 = <db.row.<dlocal._for>.uid>
ref2 = <db.row.<dlocal._for>.spouse>
button 50 <eval (<local.y> + 3)> 04b9 04ba 1 0 <eval (<local._for> + 2001)>
dtext 70 <local.y> <qval (<ref2.isonline>) ? 03e:33> <ref2.name>
button 280 <eval (<local.y> + 3)> 04b9 04ba 1 0 <eval (<local._for> + 3001)>
dtext 300 <local.y> <qval (<ref1.isonline>) ? 03e:33> <ref1.name>
button 445 <eval (<local.y> - 3)> 4017 4018 1 0 <eval (<local._for> + 1001)>
button 480 <eval (<local.y> - 3)> 4025 4024 1 0 <eval (<local._for> + 1)>
if (<eval (<local._for> % 8)> == 0) && (<local._for> < <eval (<db.row.numrows> - 1)>)
local.page ++
button 100 20 4005 4006 0 <dlocal.page> 0
page <dlocal.page>
local.y = 60
button 20 20 4014 4015 0 <eval (<local.page> - 1)> 0
endif
endfor
endif
[DIALOG d_family_confirmation BUTTON]
ON=0
sdialog d_family
ON=1 1000
DB.QUERY "SELECT * FROM chars WHERE family='<surname>' AND fullmember=0 LIMIT <eval (<argn1> - 1)>,1"
ref1 = <db.row.0.uid>
ref2 = <db.row.0.spouse>
serv.b @,,1 <ref2.name> ve <ref1.name> <ref2.surname>'a mutluluklar dileriz.
serv.newitem i_ring_family,1,<ref1>,1
DB.QUERY "SELECT ring_hue FROM families WHERE name='<ref2.surname>'"
new.color = <db.row.0>
ref1.tag.name.suffix = " <ref2.surname>"
DB.EXECUTE "UPDATE chars SET fullmember=1 WHERE uid='<ref1>'"
sdialog d_family
ON=1001 2000
DB.QUERY "SELECT * FROM chars WHERE family='<surname>' AND fullmember=0 LIMIT <eval (<argn1> - 1001)>,1"
ref1 = <db.row.0.uid>
ref2 = <db.row.0.spouse>
DB.EXECUTE "UPDATE chars SET spouse=0 WHERE uid='<ref2>'"
DB.EXECUTE "DELETE FROM chars WHERE uid='<ref1>'"
sdialog d_family
ON=2001 3000
DB.QUERY "SELECT * FROM chars WHERE family='<surname>' AND fullmember=0 LIMIT <eval (<argn1> - 2001)>,1"
ctag.family.member = <db.row.0.spouse>
sdialog d_family_member
ON=3001 4000
DB.QUERY "SELECT * FROM chars WHERE family='<surname>' AND fullmember=0 LIMIT <eval (<argn1> - 3001)>,1"
ctag.family.member = <db.row.0.uid>
sdialog d_family_member
[FUNCTION uyeal]
if !<isempty <argo.surname>>
sdialog d_family
sysmessage @,,1 <argo.name> baÅŸka bir aileye mensup.
return 1
endif
trysrc <argo> sdialog d_family_member_confirm
[DIALOG d_family_member_confirm]
200,200
noclose
page 0
resizepic 0 0 5054 400 110
gumppictiled 10 10 380 90 2624
checkertrans 10 10 380 90
dhtmlgump 20 20 360 40 1 0 <surname> ailesine katılmak ister misiniz?
button 50 70 4005 4006 1 0 1
dtext 85 72 1153 Evet
button 250 70 4005 4006 1 0 0
dtext 285 72 1153 Hayır
[DIALOG d_family_member_confirm BUTTON]
ON=0
sysmessage @,,1 <src.name> ailenize katılmak istemiyor.
trysrc <uid> sdialog d_family
ON=1
DB.EXECUTE "INSERT INTO chars VALUES ('<src.>','<src.name>','<surname>',0,1) ON DUPLICATE KEY UPDATE family='<surname>', spouse=0, fullmember=1"
serv.newitem i_ring_family,1,<src>,1
DB.QUERY "SELECT ring_hue FROM families WHERE name='<surname>'"
new.color = <db.row.0>
sysmessage @,,1 <src.name> ailenize katıldı.
src.tag.name.suffix = " <surname>"
[DIALOG d_family_demolish]
200,200
noclose
page 0
resizepic 0 0 5054 400 110
gumppictiled 10 10 380 90 2624
checkertrans 10 10 380 90
dhtmlgump 20 20 360 40 1 0 Aileyi yıkmak istediğinizden emin misiniz?
button 50 70 4005 4006 1 0 1
dtext 85 72 1153 Evet
button 250 70 4005 4006 1 0 0
dtext 285 72 1153 Hayır
[DIALOG d_family_demolish BUTTON]
ON=0
sdialog d_family
ON=1
DB.EXECUTE "DELETE FROM families WHERE name='<surname>'"
DB.QUERY "SELECT * FROM chars WHERE family='<surname>'"
if <db.row.numrows>
for 0 <eval (<db.row.numrows> - 1)>
ref1 = <db.row.<dlocal._for>.uid>
ref1.consume i_ring_family
ref1.tag.name.suffix =
endfor
endif
DB.EXECUTE "DELETE FROM chars WHERE family='<surname>'"
[DIALOG d_family_leave]
200,200
noclose
page 0
resizepic 0 0 5054 400 110
gumppictiled 10 10 380 90 2624
checkertrans 10 10 380 90
dhtmlgump 20 20 360 40 1 0 <surname> ailesinden ayrılmak istiyor musunuz? <qval (<ismale>) ? Devam ederseniz eşinizde aileden atılacak.:>
button 50 70 4005 4006 1 0 1
dtext 85 72 1153 Evet
button 250 70 4005 4006 1 0 0
dtext 285 72 1153 Hayır
[DIALOG d_family_leave BUTTON]
ON=0
sdialog d_family
ON=1
if <ismale>
ref1 = <spouse>
if <ref1>
ref1.consume i_ring_family
ref1.tag.name.suffix =
DB.EXECUTE "DELETE FROM chars WHERE uid='<ref1>'"
endif
elif <isfemale>
ref1 = <spouse>
if <ref1>
DB.EXECUTE "UPDATE chars SET spouse=0 WHERE uid='<ref1>'"
endif
endif
consume i_ring_family
tag.name.suffix =
DB.EXECUTE "DELETE FROM chars WHERE uid='<uid>'"
[DIALOG d_family_divorce]
200,200
page 0
resizepic 0 0 5054 400 110
gumppictiled 10 10 380 90 2624
checkertrans 10 10 380 90
dhtmlgump 20 20 360 40 1 0 Eşinizden boşanmak istiyor musunuz? Eşiniz aileden atılacak, sizin aile üyeliğiniz devam edecek.
button 50 70 4005 4006 1 0 1
dtext 85 72 1153 Evet
button 250 70 4005 4006 1 0 0
dtext 285 72 1153 Hayır
[DIALOG d_family_divorce BUTTON]
ON=0
sdialog d_family
ON=1
ref1 = <spouse>
if <ref1>
ref1.consume i_ring_family
ref1.tag.name.suffix =
DB.EXECUTE "UPDATE chars SET spouse=0 WHERE uid='<uid>'"
DB.EXECUTE "DELETE FROM chars WHERE uid='<ref1>'"
endif
sdialog d_family
[DIALOG d_family_member]
70,100
page 0
resizepic 0 0 5054 320 220
gumppictiled 10 10 300 200 2624
checkertrans 10 10 300 200
ref1 = <ctag.family.member>
dtext 20 20 1153 Ä°sim:
dtext 120 20 <qval (<ref1.ismale>) ? 0122 ♂:0e6 ♀>
dtext 135 20 <qval (<ref1.isonline>) ? 03e:33> <ref1.name> <ref1.surname>
dtext 20 45 1153 Skill Toplamı:
dtext 135 45 1153 <fval <ref1.skilltotal>>
dtext 20 70 1153 Stats:
dtext 135 70 1153 <ref1.str> str, <ref1.dex> dex, <ref1.int> int
dtext 20 95 1153 Fame/Karma:
dtext 135 95 1153 <ref1.fame>/<ref1.karma>
dtext 20 120 1153 Kills/Deaths:
dtext 135 120 1153 <ref1.kills>/<ref1.deaths>
dtext 20 145 1153 EÅŸ:
ref2 = <ref1.spouse>
if <ref2>
button 115 147 04b9 04ba 1 0 1
dtext 135 145 <qval (<ref2.isonline>) ? 03e:33> <ref2.name>
else
dtext 135 145 1153 -
endif
if <ispatriarch>
button 190 180 4017 4018 1 0 2
dtext 225 182 33 Aileden At!
endif
[DIALOG d_family_member BUTTON]
ON=0
sdialog d_family
ON=1
ctag.family.member = <uid.<ctag.family.member>.spouse>
sdialog d_family_member
ON=2
ctag.family.banishment = <ctag.family.member>
sdialog d_family_member_banish
[DIALOG d_family_member_banish]
200,200
noclose
page 0
resizepic 0 0 5054 400 110
gumppictiled 10 10 380 90 2624
checkertrans 10 10 380 90
ref1 = <ctag.family.banishment>
dhtmlgump 20 20 360 40 1 0 <ref1.name>'i aileden atmak istiyor musunuz? <qval (<ref1.ismale> && <ref1.spouse>) ? Devam ederseniz <ref1.name>'in eşi de aileden atılacak.:>
button 50 70 4005 4006 1 0 1
dtext 85 72 1153 Evet
button 250 70 4005 4006 1 0 0
dtext 285 72 1153 Hayır
[DIALOG d_family_member_banish BUTTON]
ON=0
sdialog d_family_member
ON=1
ref1 = <ctag.family.banishment>
if <ref1.ismale>
ref2 = <ref1.spouse>
if <ref2>
ref2.consume i_ring_family
ref2.tag.name.suffix =
DB.EXECUTE "DELETE FROM chars WHERE uid='<ref2>'"
endif
elif <ref1.isfemale>
ref2 = <ref1.spouse>
if <ref2>
DB.EXECUTE "UPDATE chars SET spouse=0 WHERE uid='<ref2>'"
endif
endif
ref1.consume i_ring_family
ref1.tag.name.suffix =
DB.EXECUTE "DELETE FROM chars WHERE uid='<ref1>'"
sdialog d_family
[EOF][Plevel 1]
a
[function a]
if (strmatch("<args>",""))
src.hata Boş mesaj gönderemezsin!
elseif (strmatch("<args>","<tag.yazi>"))
src.hata Yazı tekrarı yapamazsın!
elseif !(<src.tag0.ailem>)
src.hata Bir aileye üye değilsin!
return 1
else
tag0.yazi <args>
serv.allclients ailechatci <args>
endif
[function ailechatci]
if (strmatch('<src.tag0.ailem>','<tag0.ailem>')
sysmessage @75,,1 [<src.name>]: <args>
endif
[ITEMDEF i_aile_deed]
id=i_deed
type=t_script
name=Aile Deed
value=1
on=@create
color=0455
attr=04
On=@Click
message @799,,1 [<serv.name>]
message @07a1,,1 <name>
return 1
on=@dclick
IF (<topobj.uid> != <src.uid>)
src.hata Bu eşyayı kullanabilmek için çantanızda olmalı!
return 1
elseif (<src.tag0.ailem>)
src.hata Sizin bir aileniz mevcut!
return 1
endif
src.dialogclose d_aileci
src.dialog d_aileci
return 1
[DIALOG d_aileci]
150,20
resizepic 0 0 <var.theme1> 330 200
resizepic 10 10 <var.theme2> 310 180
dhtmlgump 40 10 250 25 10 0 <def.center><def.bfont_red>Uo-Developer Scripting Yarışması
dhtmlgump 20 40 350 20 0 0 <def.bfont_black>Merhaba <src.name>,
dhtmlgump 20 60 350 20 0 0 <def.bfont_black>Soyadınız <def.bfont_red>en az 2, en fazla 16 <def.bfont_black>karakter olmalıdır
resizepic 40 84 <var.theme2> 250 25
dtextentry 42 85 222 35 1153 1 Soyadınızı bu bölüme yazınız
dhtmlgump 60 118 350 20 0 0 <def.bfont_black>Ailenin adını onaylıyormusun <src.name>?
dhtmlgump 75 148 350 20 0 0 <def.bfont_green>Onayla
dhtmlgump 220 148 350 20 0 0 <def.bfont_red>Kapat
dhtmlgump 60 168 460 20 0 0 <def.bfont_black><def.bfont_size3>Sunucuda şuana kadar <def.bfont_red><eval <var0.kurdum>> aile <def.bfont_black>kurulmuştur
button 40 150 00000039 0000003b 1 0 1
button 117 150 0000003b 00000039 1 0 1
button 185 150 00000039 0000003b 1 0 2
button 255 150 0000003b 00000039 1 0 2
[DIALOG d_aileci button]
on 1
if (strlen(<argtxt[1]>) > 16) || (strlen(<argtxt[1]>) < 2)
src.hata Soyadınız en az 2, en fazla 16 karakter olmalıdır!
return 1
elseif (<badchar <argtxt[1]>>)
src.hata Soyadınızda sadece harf ve ( $ ' ) karakterleri bulunabilir!
return 1
elseif !(<src.findid.i_aile_deed>)
src.hata Sadece çantanızda kullanabilirsiniz!
return 1
endif
local.argtxt <argtxt[1]>
for 15
if (<isnum <strsub <eval <local._for>> 1 <local.argtxt>>>)
src.hata Soyadınızda rakam kullanmazsınız!
return 1
endif
endfor
if (<src.tag0.ailem>)
src.hata Bir aile üyesisiniz!
return 1
endif
forplayers 99999
obj <uid>
if (<obj.tag0.ailem>)
ref1 <obj.tag.ailem>
if (strmatch('<ref1.tag.aileisim>','<local.argtxt>'))
src.hata <local.argtxt> ailesi daha önceden kurulmustur.
var.kurdum +=1
return 1
endif
endif
endfor
serv.allclients sysmessage @0799,,1 [-Aile Duyuru-]
serv.allclients sysmessage @0bb2,,1 <local.argtxt> ailesi kurulmustur.
src.tag0.aileony1 0
serv.newitem i_aile_hafiza
new.equip
new.tag.aileisim <local.argtxt>
src.tag.ailem <new.uid>
src.tag.name.suffix " <local.argtxt>"
new.tag.reis <src.uid>
new.tag0.uyesayisi += 1
new.tag0.uye<dnew.tag0.uyesayisi> <src.uid>
src.sysmessage @07a1,,1 Aile menüsünü kullanabilmek için (.aile) komutunu kullanınız.
src.consume 1 i_aile_deed
return 1
[Plevel 1]
aile
aileonline
[function aile]
if !(<src.tag0.ailem>)
src.hata Bir aile üyesi veya başkanı değilsiniz!
return 1
endif
src.sdialog d_aile_menu
return 1
[DIALOG d_aile_menu]
100,30
resizepic 0 0 <var.theme1> 250 400
resizepic 10 10 <var.theme2> 230 380
obj <src.tag.ailem>
gumppic 10 40 00000032
gumppic 97 40 00000032
gumppic 10 95 00000032
gumppic 97 95 00000032
gumppic 10 150 00000032
gumppic 97 150 00000032
gumppic 10 205 00000032
gumppic 97 205 00000032
dhtmlgump 50 10 150 25 10 0 <def.center><def.bfont_red><obj.tag.aileisim> Ailesi
dhtmlgump 40 60 170 25 10 0 <def.center><def.bfont_red>Aile Adı : <def.bfont_black><obj.tag.aileisim>
dhtmlgump 40 115 170 25 10 0 <def.center><def.bfont_red>Üye Sayısı : <def.bfont_black><eval <obj.tag0.uyesayisi>>
dhtmlgump 40 170 170 25 10 0 <def.center><def.bfont_red>Aile Kurucusu : <def.bfont_black><uid.<obj.tag.reis>.name>
dhtmlgump 55 225 140 25 10 0 <def.center><def.bfont_blue>Yeni Üye Alımı
dhtmlgump 55 265 140 25 10 0 <def.center><def.bfont_blue>Üye Listesi
dhtmlgump 55 305 140 25 10 0 <def.center><def.bfont_green>Online Üyeler
if (<obj.tag.reis> == <src.uid>)
dhtmlgump 55 345 140 25 10 0 <def.center><def.bfont_red>Aileyi Yık!
button 18 350 00000039 0000003b 1 0 4
button 199 350 0000003b 00000039 1 0 4
else
dhtmlgump 55 345 140 25 10 0 <def.center><def.bfont_red>Aileden Ayrıl!
button 18 350 00000039 0000003b 1 0 5
button 199 350 0000003b 00000039 1 0 5
endif
button 18 230 00000039 0000003b 1 0 1
button 199 230 0000003b 00000039 1 0 1
button 18 270 00000039 0000003b 1 0 2
button 199 270 0000003b 00000039 1 0 2
button 18 310 00000039 0000003b 1 0 3
button 199 310 0000003b 00000039 1 0 3
[DIALOG d_aile_menu button]
on 1
obj <src.tag.ailem>
src.targetf f_uyeal
src.sysmessage @07a1,,1 Ailenize üye etmek istediğiniz kişiyi seçiniz
return 1
on 2
obj <src.tag.ailem>
if (<obj.tag0.uyesayisi>)
src.ctag.asayfa 1
src.dialogclose d_aileuyelist
src.dialog d_aileuyelist
return 1
endif
src.hata Üye bulunamadı!
return 1
on 3
src.aileonline
return 1
on 4
var0.aile1 -=1
obj <src.tag.ailem>
ref1 <src.tag.ailem>
for <ref1.tag.uyesayisi>
obj <ref1.tag.uye<dlocal._for>>
obj.tag.ailem
obj.tag.name.suffix
obj.sysmessage @07a1,,1 <ref1.tag.aileisim> ailesi yikilmistir.
endfor
serv.allclients sysmessage @0bb2,,1 <ref1.tag.aileisim> isimli aile yikilmistir.
ref1.remove
return 1
on=5
obj <src.tag.ailem>
if !(<src.tag0.ailem> == <obj>)
src.sysmessage @066d,,1 Siz zaten bu ailede degilsiniz.
return 1
endif
for 1 <obj.tag.uyesayisi>
if (<obj.tag0.uye<dlocal._for>> == <src.uid>)
local.kacinciuye <dlocal._for>
endif
endfor
for <dlocal.kacinciuye> <obj.tag.uyesayisi>
if !(<dlocal._for> == <obj.tag.uyesayisi>)
obj.tag.uye<dlocal._for> <obj.tag.uye<eval <dlocal._for>+1>>
endif
endfor
try uid.<obj.tag.reis>.sysmessage @07a1,,1 <src.name> isimli oyuncu ailenizden ayrildi.
src.sysmessage @07a1,,1 <obj.tag.aileisim> isimli aileden ayrildiniz.
obj.tag.uyesayisi -= 1
src.tag.ailem
src.tag.name.suffix
return 1
[function f_uyeal]
obj <argo>
ref1 <src.tag.ailem>
if (<eval <uid.<src.tag0.ailem>.tag0.uyesayisi>> > 30)
src.hata Üye sayısı 30'u geçemez
return 1
elif (<obj.tag0.ailem>)
src.hata BU kişi bir aileye üye!
return 1
elseif !(<obj.isplayer>)
src.hata Sadece oyuncuları aileye alabilirsiniz!
return 1
endif
src.sysmessage @07a1,,1 <obj.name> isimli kisiye teklif yollandi.
TRYSRC <obj.uid> dialogclose d_aile_teklif
TRYSRC <obj.uid> dialog d_aile_teklif
return 1
[DIALOG d_aile_teklif]
0,0
page 0
resizepic 0 0 <var.theme1> 270 180
resizepic 10 10 <var.theme2> 250 160
dhtmlgump 25 10 220 25 10 0 <def.center><def.bfont_red>Uo-Developer Scripting Yarışması
dhtmlgump 18 50 300 20 0 0 <def.bfont_red><name> <def.bfont_black>isimli oyuncu sizi <def.bfont_red><obj.tag.aileisim> <def.bfont_black>ailesine
dhtmlgump 18 70 300 20 0 0 <def.bfont_black>davet ediyor. Daveti onaylıyormusunuz?
dhtmlgump 60 105 50 20 0 0 <def.bfont_green>Onayla
dhtmlgump 176 105 50 20 0 0 <def.bfont_red>Kapat
dhtmlgump 20 140 300 20 0 0 <def.bfont_red><obj.tag.aileisim> <def.bfont_black>ailesinde toplam <def.bfont_red><eval <obj.tag0.uyesayisi>> üye <def.bfont_black>mevcuttur.
button 28 107 00000039 0000003b 1 0 1
button 96 107 0000003b 00000039 1 0 1
button 145 107 00000039 0000003b 1 0 2
button 210 107 0000003b 00000039 1 0 2
[dialog d_aile_teklif button]
on 1
if (<src.tag0.ailem>)
src.sysmessage @066d,,1 Sizin zaten bir aileniz var.
sysmessage @066d,,1 <src.name> isimli kisinin zaten bir ailesi var.
return 1
endif
src.tag.ailem <tag.ailem>
ref1 <src.tag.ailem>
src.tag.name.suffix " <ref1.tag.aileisim>"
ref1.tag0.uyesayisi += 1
ref1.tag0.uye<dref1.tag0.uyesayisi> <src.uid>
src.sysmessage @07a1,,1 Tebrikler.<ref1.tag.aileisim> isimli aileye üye oldunuz.
return 1
on 2
src.hata <src.name> teklifinizi kabul etmedi.
return 1
[dialog d_aileuyelist]
0,0
resizepic 0 0 <var.theme1> 390 380
resizepic 10 10 <var.theme2> 370 360
dhtmlgump 90 10 220 25 10 0 <def.center><def.bfont_red>Uo-Developer Scripting Yarışması
ref1 <src.tag.ailem>
dhtmlgump 40 50 100 20 0 0 <def.bfont_blue><def.u>Üye Adı</u>
dhtmlgump 160 50 100 20 0 0 <def.bfont_red><def.u>Kill</u>
dhtmlgump 210 50 100 20 0 0 <def.bfont_red><def.u>Death</u>
dhtmlgump 260 50 100 20 0 0 <def.bfont_blue><def.u>Bulunduğu Yer</u>
dhtmlgump 40 300 100 20 0 0 <def.bfont_white>Önceki Sayfa
dhtmlgump 260 300 100 20 0 0 <def.bfont_white>Sonraki Sayfa
if !(<dsrc.ctag0.asayfa> == 1)
button 240 300 55 55 1 0 112
endif
local.az <dref1.tag0.uyesayisi>
local.a <eval <dsrc.ctag.asayfa>*11>
if (<dlocal.az> > <dlocal.a>)
button 20 300 55 55 1 0 111
local.te 1
endif
local.awe <eval <dsrc.ctag.asayfa> -1>
local.awe <eval <dlocal.awe>*11>
local.abc <eval <dlocal.az> - <dlocal.awe>>
local.satir 80
for <eval <qval (<dlocal.te> == 1)?11:<dlocal.abc>>>
local.aa <eval <dsrc.ctag0.asayfa> -1>
local.aa <eval <dlocal.aa>*11>
local.aa +=<dlocal._for>
obj=<dref1.tag0.uye<dlocal.aa>>
if !(<obj> == 00)
dhtmlgump 260 <eval <dlocal.satir>+1> 120 20 0 0 <qval (<obj.isonline>)?<qval (<obj.region.guarded> == 1)?<def.bfont_dblue><obj.region.name>:<def.bfont_red><obj.region.name>>:<def.bfont_black>>
dhtmlgump 160 <eval <dlocal.satir>+1> 50 20 0 0 <obj.kills>
dhtmlgump 210 <eval <dlocal.satir>+1> 50 20 0 0 <obj.deaths>
dhtmlgump 40 <eval <dlocal.satir>+1> 100 20 0 0 <qval (<obj.isonline> == 1)?<def.bfont_dgreen><obj.name>:<obj.name>>
button 20 <dlocal.satir> 55 55 1 0 <dlocal._for>
local.satir +=20
endif
endfor
[dialog d_aileuyelist button]
on 111
src.dialogclose d_aileuyelist
src.ctag.asayfa +=1
src.sdialog d_aileuyelist
on 112
src.dialogclose d_aileuyelist
src.ctag.asayfa -=1
src.sdialog d_aileuyelist
on=1 11
local.aa <eval <dsrc.ctag.asayfa> -1>
local.aa <dlocal.aa>*11
local.aa +=<eval <argn>>
src.ctag0.hangiuye <dlocal.aa>
src.dialogclose d_aileuyelist_2
src.dialog d_aileuyelist_2
src.tag0.uyebu <obj.uid>
[dialog d_aileuyelist_2]
0,0
resizepic 0 0 <var.theme1> 390 320
resizepic 10 10 <var.theme2> 370 300
dhtmlgump 80 10 250 25 10 0 <def.center><def.bfont_red>Uo-Developer Scripting Yarışması
ref1=<src.tag.ailem>
obj=<dref1.tag0.uye<dsrc.ctag.hangiuye>>
dhtmlgump 40 50 350 20 0 0 <def.bfont_blue>Üye Adı : <def.bfont_black><obj.name>
dhtmlgump 40 90 350 20 0 0 <def.bfont_red>Kill : <def.bfont_black><obj.kills>
dhtmlgump 40 110 350 20 0 0 <def.bfont_red>Deaths : <def.bfont_black><obj.deaths>
dhtmlgump 40 130 350 20 0 0 <def.bfont_green>Online Kaldığı Saat : <def.bfont_black><eval <obj.ACCOUNT.TOTALCONNECTTIME>/60> Saat
dhtmlgump 40 150 350 20 0 0 <def.bfont_blue>Fame : <def.bfont_black><obj.fame>
dhtmlgump 40 170 350 20 0 0 <def.bfont_blue>Karma : <def.bfont_black><obj.karma>
dhtmlgump 40 190 350 20 0 0 <def.bfont_red>Hits : <def.bfont_black><obj.str>/<obj.hits>
dhtmlgump 40 210 350 20 0 0 <def.bfont_blue>Skill Toplamı : <def.bfont_black><fval <obj.skilltotal>>
dhtmlgump 40 230 350 20 0 0 <def.bfont_green>Son Online Tarihi : <def.bfont_black><obj.ACCOUNT.LASTCONNECTDATE>
if (<ref1.tag.reis> == <src.uid>)
dhtmlgump 60 260 350 20 0 0 <def.bfont_red>Aileden Kov!
button 40 260 55 55 1 0 1
endif
[dialog d_aileuyelist_2 button]
on 0
obj <src.tag.ailem>
src.ctag.asayfa 1
src.dialogclose d_aileuyelist
src.dialog d_aileuyelist
return 1
on 1
ref2=<src.tag0.uyebu>
ref1=<src.tag.ailem>
if !(<ref2.tag0.ailem> == <src.tag0.ailem>)
src.sysmessage @066d,,1 Bu kisi sizin ailenizde degil.
return 1
elseif (<ref1.tag.reis> == <ref2.uid>)
src.sysmessage @066d,,1 Kendi kendinizi aileden atamazsiniz.
return 1
endif
for <dsrc.ctag.hangiuye> <ref1.tag.uyesayisi>
if !(<dlocal._for> == <ref1.tag.uyesayisi>)
ref1.tag.uye<dlocal._for> <ref1.tag.uye<eval <dlocal._for>+1>>
endif
endfor
ref2.tag.ailem
ref2.tag.name.suffix
ref2.sysmessage @066d,,1 <ref1.tag.aileisim> ailesinden atildiniz.
src.sysmessage @066d,,1 <ref2.name> isimli kisiyi aileden atildi.
ref1.tag.uyesayisi -= 1
return 1
[itemdef i_aile_hafiza]
name Aile hafiza
id i_memory
weight 0
type t_eq_script
layer layer_special
ON=@Create
ATTR=attr_invis|attr_decay
ON=@Equip
timer -1
ON=@timer
timer -1
return 1
[FUNCTION badchar]
if !(<EVAL STRLEN(<ARGS>)>) || (STRMATCH("*[[]*","<ARGS>")) || (STRMATCH("*]*","<ARGS>")) || (STRMATCH("*[(]*","<ARGS>")) || (STRMATCH("*-*","<ARGS>")) || (STRMATCH("*[*}`>?´;:^%¨!"<#.@_~|=+&/æ{]*","<ARGS>"))
RETURN 1
ELSE
RETURN 0
ENDIF
[function taglarinhepsinisil]
for x 1 20
try uid.<tag0.ailem>.tag.onlinename<dlocal.x> 0
try uid.<tag0.ailem>.tag.onlinedoldu<dlocal.x> 0
try uid.<tag0.ailem>.tag.uyeonlineuid<dlocal.x> 0
try uid.<tag0.ailem>.tag.uyeonlinedoldu<dlocal.x> 0
endfor
[function aileonline]
if !(<src.tag0.ailem>)
src.sysmessage @066d,,1 Bir aile'niz bulunmuyor.
return 1
endif
src.ai1
dialogclose d_aileonline
DIALOG d_aileonline
return 1
[function ai1]
src.taglarinhepsinisil
serv.allclients tag0.yapandeedid <src.tag0.ailem>
serv.allclients ai2
[function ai2]
if (<tag0.ailem> == <src.tag0.ailem>)
for 1 20
if !(0<uid.<tag0.ailem>.tag.uyeonlinedoldu<eval <local._for>>>)
try uid.<tag0.ailem>.tag.uyeonlinedoldu<eval <local._for>>=1
try uid.<tag0.ailem>.tag.onlinename<eval <local._for>>=<name>
try uid.<tag0.ailem>.tag.uyeonlineuid<eval <local._for>>=<uid>
return 1
Endif
endfor
Endif
[dialog d_aileonline]
50, 50
page 0
resizepic 0 0 <var.theme1> 390 325
resizepic 10 10 <var.theme2> 370 305
dhtmlgump 80 10 250 25 10 0 <def.center><def.bfont_red>Uo-Developer Scripting Yarışması
page 1
dhtmlgump 85 265 350 20 0 0 <def.bfont_red>Sonraki Sayfa
button 50 267 57 57 0 2
for x 1 10
gumppic 40 (<eval <dlocal.x>*20>+42) 57
dhtmlgump 75 (<eval <dlocal.x>*20>+40) 150 20 0 0 <def.bfont_dgreen><uid.<src.tag0.ailem>.tag0.onlinename<dlocal.x>>
endif
endfor
page 2
dhtmlgump 70 269 350 20 0 0 <def.bfont_red>Önceki Sayfa
button 50 267 57 57 0 1
for x 11 20
gumppic 40 (<eval <dlocal.x>*20>-158) 57
dhtmlgump 75 (<eval <dlocal.x>*20>-160) 150 20 0 0 <def.bfont_dgreen><uid.<src.tag0.ailem>.tag0.onlinename<dlocal.x>>
endfor[defname ailesistemi_ailesabitleri]
ailesistemi_ailegirisucreti 100000
ailesistemi_maxuyesayisi 22
[itemdef i_ailesistemi_ailekurdeed]
id i_deed
name Aile Kurma Blgesi
on=@create
color 2026
on=@dclick
if (<topobj.uid>!=<src.uid>)
src.smx Üzerinizde olmalı..
else
dialog d_ailesistemi_ailekur
endif
return 1
[dialog d_ailesistemi_ailekur]
220,200
nomove
src.dialogclose d_ailesistemi_ailemenu_reis
src.dialogclose d_ailesistemi_ailemenu_ayrintili_reis
src.dialogclose d_ailesistemi_ailekur
src.dialogclose d_ailesistemi_aileyik
resizepic 0 0 61321 400 200
dhtmlgump 30 50 170 20 0 0 <def.bfont_white>Alacağınız soyadını yazınız:
resizepic 182 45 2620 170 31
dtextentry 190 50 150 20 920 1
button 185 140 4023 4025 1 0 1
[dialog d_ailesistemi_ailekur Button]
on=1
if (<cont.type>==t_eq_trade_window)
return 1
elif !(<src.restest 1 i_ailesistemi_ailekurdeed>)
src.smx Üzerinizde bir aile kurma belgesi bulunmuyor..
return 1
endif
local.soyadi <argtxt[1]>
if (<src.tag0.ailesistemi_ailemvar>)
src.smx Zaten bir ailedesiniz, bir aile kurabilmek için önce ailenizden çıkmalısınız..
return 1
elif !(<karakterkontrol 0,'<local.soyadi>',harf> == 1)
src.smx İsimde işaret, sayı, boşluk veya Türkçe karakter kullanılamaz..
return 1
elif (strlen(<local.soyadi>) > 14) || (strlen(<local.soyadi>) < 3)
src.smx Soyadın uzunluğu en az 3, en çok 14 karakter olmalıdır..
return 1
endif
if (<var0.__ailesistemi_aile_<local.soyadi>>)
src.smx Aile kurulamadı: <local.soyadi> adında bir aile zaten var..
return 1
endif
var.__ailesistemi_aile_<local.soyadi> 1
src.name <src.name> <local.soyadi>
src.tag.ailesistemi_ailemvar 1
src.tag.ailesistemi_soyadim <local.soyadi>
src.tag.ailesistemi_reisimben 1
serv.allclients smg <local.soyadi> ailesi kurulmuştur, aile reisi <src.name>'dir. Kendilerine başarılar diliyoruz..
src.consume 1 i_ailesistemi_ailekurdeed
[plevel 1]
ailemenu
[function ailemenu]
src.ctag.ailesistemi_kolyemenu_uye 0
if (<src.tag0.ailesistemi_reisimben>)
src.dialog d_ailesistemi_ailemenu_reis
elif (<src.tag0.ailesistemi_ailemvar>)
src.dialog d_ailesistemi_ailemenu_uye
else
src.smx Bu komutu kullanmak için aileniz olmalı..
endif
[dialog d_ailesistemi_ailemenu_reis]
0,0
src.dialogclose d_ailesistemi_ailemenu_reis
src.dialogclose d_ailesistemi_ailemenu_ayrintili_reis
src.dialogclose d_ailesistemi_ailekur
src.dialogclose d_ailesistemi_aileyik
local.uyeno <src.ctag.ailesistemi_kolyemenu_uye>
resizepic 260 200 61321 290 220
button 310 231 2117 2118 1 0 1
if (<src.ctag.ailesistemi_kolyemenu_uye>!=0)
button 320 361 9766 9767 1 0 44
endif
if (<var0.__ailesistemi_aile_<src.tag.ailesistemi_soyadim>_uye<eval <local.uyeno>+1>>)
button 473 361 9762 9763 1 0 55
endif
dtext 330 226 0790 Aileye adam al
if (<var0.__ailesistemi_aile_<src.tag.ailesistemi_soyadim>_uye<dlocal.uyeno>>)
local.lastobj=<obj>
obj=<var0.__ailesistemi_aile_<src.tag.ailesistemi_soyadim>_uye<dlocal.uyeno>>
button 305 305 2117 2118 1 0 2
dtext 325 300 455 Ayrıntılı bilgi
dtext 384 361 455 Üye <eval <local.uyeno>+1>
dtext 300 260 455 İsim:
dtext 340 260 0790 <obj.name>
dtext 300 280 <qval (<obj.isonline>)?76:31> <qval (<obj.isonline>)?Online:Offline>
src.ctag.ailesistemi_kolyemenu_bakilanuyeuid <obj.uid>
obj=<local.lastobj>
endif
[dialog d_ailesistemi_ailemenu_reis button]
on=1,55
if !(<src.tag0.ailesistemi_reisimben>) || !(<src.tag0.ailesistemi_ailemvar>)
return 1
endif
if (<argn>==1)
src.targetf f_ailesistemi_aileyeadamal <src.tag.ailesistemi_soyadim>
src.smx Kimi aileye alacaksınız?
elif (<argn>==2)
src.dialog d_ailesistemi_ailemenu_ayrintili_reis
elif (<argn>==44)
src.ctag.ailesistemi_kolyemenu_uye --
src.dialog d_ailesistemi_ailemenu_reis
elif (<argn>==55)
src.ctag.ailesistemi_kolyemenu_uye ++
src.dialog d_ailesistemi_ailemenu_reis
endif
[function f_ailesistemi_aileyeadamal]
if !(<argo.isplayer>)
src.smx Sadece oyuncuları aileye alabilirsiniz..
elif (<argo.uid>==<src.uid>)
src.smx Kendinizi aileye alamazsınız..
elif (<argo.tag0.ailesistemi_ailemvar>)
src.smx <argo.name> zaten bir aileye üye..
else
src.face <argo.uid>
src.smg <argo.name> adlı kişiye soruluyor..
argo.ctag.ailesistemi_aileadi <args>
trysrc <argo.uid> src.dialog d_ailesistemi_uyekabul
endif
[dialog d_ailesistemi_uyekabul]
270,170
nomove
src.dialogclose d_ailesistemi_uyekabul
resizepic 0 0 61321 200 260
dhtmlgump 15 50 185 60 0 0 <def.center><def.bfont_yellow><src.ctag.ailesistemi_aileadi> adlı aileye davet edildiniz, girecek misiniz?<def.centere>
dhtmlgump 42 180 40 20 0 0 <def.bfont_white>Evet
button 40 200 4005 4007 1 0 1
dhtmlgump 142 180 40 20 0 0 <def.bfont_white>Hayır
button 140 200 4017 4019 1 0 0
[dialog d_ailesistemi_uyekabul button]
on=1
if !(<src.restest <def0.ailesistemi_ailegirisucreti> i_gold>)
src.smx Aileye girmek için <ddef0.ailesistemi_ailegirisucreti> kadar altınınız olmalı..
elif (<var0.__ailesistemi_aile_<src.ctag.ailesistemi_aileadi>_uye<def0.ailesistemi_maxuyesayisi>>)
src.smx Ailede maksimum üye sayısı olan <ddef0.ailesistemi_maxuyesayisi> üye zaten var..
elif (<src.tag0.ailesistemi_ailemvar>)
src.smx Zaten bir aileye üyesiniz, başka bir aileye girebilmek için önce ailenizden çıkmalısınız..
elif !(<var0.__ailesistemi_aile_<src.ctag.ailesistemi_aileadi>>)
src.smx Aile siz giremeden yıkılmış..
else
src.tag.ailesistemi_ailemvar 1
while (<var0.__ailesistemi_aile_<src.ctag.ailesistemi_aileadi>_uye<dlocal.s>>)
local.s ++
endwhile
var.__ailesistemi_aile_<src.ctag.ailesistemi_aileadi>_uye<dlocal.s> <src.uid>
src.soyadsil
src.name <src.name> <src.ctag.ailesistemi_aileadi>
src.tag.ailesistemi_soyadim <src.ctag.ailesistemi_aileadi>
src.smx <src.ctag.ailesistemi_aileadi> adlı aileye başarı ile girdiniz..
src.consume <def0.ailesistemi_ailegirisucreti> i_gold
endif
[dialog d_ailesistemi_ailemenu_ayrintili_reis]
0,0
src.dialogclose d_ailesistemi_ailemenu_ayrintili_reis
local.lastobj=<obj>
obj=<src.ctag.ailesistemi_kolyemenu_bakilanuyeuid>
resizepic 210 170 5100 275 290
resizepic 220 180 3500 255 270
dtext 240 210 455 İsim:
dtext 280 210 0790 <obj.name>
if (<obj.isonline>)
dtext 240 230 76 Online
dtext 240 250 455 Bölge: <obj.region.name>
else
dtext 240 230 31 Offline
endif
dtext 240 270 455 Fame: <obj.fame>
dtext 240 290 455 Karma: <obj.Karma>
dtext 240 310 455 Kill sayısı: <obj.dtag.killcountz>
dtext 240 330 455 Online süre: <eval <obj.account.totalconnecttime>/60>s
button 240 390 2642 2643 1 0 1
dtext 285 398 0790 Aileden at
obj=<local.lastobj>
[dialog d_ailesistemi_ailemenu_ayrintili_reis button]
on=1
local.lastobj=<obj>
obj=<src.ctag.ailesistemi_kolyemenu_bakilanuyeuid>
f_ailesistemi_ailedenadamat <src.tag.ailesistemi_soyadim>,<obj.uid>
src.smx <obj.name> ailenizden atıldı..
obj=<local.lastobj>
[dialog d_ailesistemi_ailemenu_uye]
0,0
src.dialogclose d_ailesistemi_ailemenu_uye
src.dialogclose d_ailesistemi_ailemenu_ayrintili_uye
src.dialogclose d_ailesistemi_ailekur
src.dialogclose d_ailesistemi_aileyik
local.uyeno <src.ctag.ailesistemi_kolyemenu_uye>
resizepic 260 200 61321 290 220
button 310 231 2117 2118 1 0 1
if (<src.ctag.ailesistemi_kolyemenu_uye>!=0)
button 320 361 9766 9767 1 0 44
endif
if (<var0.__ailesistemi_aile_<src.tag.ailesistemi_soyadim>_uye<eval <local.uyeno>+1>>)
button 473 361 9762 9763 1 0 55
endif
dtext 330 226 0790 Aileden çık!
if (<var0.__ailesistemi_aile_<src.tag.ailesistemi_soyadim>_uye<dlocal.uyeno>>)
local.lastobj=<obj>
obj=<var0.__ailesistemi_aile_<src.tag.ailesistemi_soyadim>_uye<dlocal.uyeno>>
button 305 305 2117 2118 1 0 2
dtext 325 300 455 Ayrıntılı bilgi
dtext 384 361 455 Üye <eval <local.uyeno>+1>
dtext 300 260 455 İsim:
dtext 340 260 0790 <obj.name>
dtext 300 280 <qval (<obj.isonline>)?76:31> <qval (<obj.isonline>)?Online:Offline>
src.ctag.ailesistemi_kolyemenu_bakilanuyeuid <obj.uid>
obj=<local.lastobj>
endif
[dialog d_ailesistemi_ailemenu_uye button]
on=1
f_ailesistemi_ailedenadamat <src.tag.ailesistemi_soyadim>,<src.uid>
src.smx Başarı ile ailenizden çıktınız..
on=2
dialog d_ailesistemi_ailemenu_ayrintili_uye
on=44
src.ctag.ailesistemi_kolyemenu_uye --
dialog d_ailesistemi_ailemenu_uye
on=55
src.ctag.ailesistemi_kolyemenu_uye ++
dialog d_ailesistemi_ailemenu_uye
[dialog d_ailesistemi_ailemenu_ayrintili_uye]
0,0
src.dialogclose d_ailesistemi_ailemenu_ayrintili_uye
local.lastobj=<obj>
obj=<src.ctag.ailesistemi_kolyemenu_bakilanuyeuid>
resizepic 210 170 5100 275 290
resizepic 220 180 3500 255 270
dtext 240 210 455 İsim:
dtext 280 210 0790 <obj.name>
if (<obj.isonline>)
dtext 240 230 76 Online
dtext 240 250 455 Bölge: <obj.region.name>
else
dtext 240 230 31 Offline
endif
dtext 240 270 455 Fame: <obj.fame>
dtext 240 290 455 Karma: <obj.Karma>
dtext 240 310 455 Kill sayısı: <obj.dtag.killcountz>
//dtext 240 330 455 Online Sure: <eval <obj.account.totalconnecttime>/60>s
//button 240 390 2642 2643 1 0 1
//dtext 285 398 0790 Aileden at
obj=<local.lastobj>
[itemdef i_ailesistemi_aileyikdeed]
id i_deed
name Aile Yikma Belgesi
on=@create
color 2021
on=@dclick
if (<topobj.uid>!=<src.uid>)
src.smx Üzerinizde olmalı..
else
dialog d_ailesistemi_aileyik
endif
return 1
[dialog d_ailesistemi_aileyik]
270,170
nomove
src.dialogclose d_ailesistemi_ailemenu_reis
src.dialogclose d_ailesistemi_ailemenu_ayrintili_reis
src.dialogclose d_ailesistemi_ailekur
src.dialogclose d_ailesistemi_aileyik
resizepic 0 0 61321 200 200
dhtmlgump 0 50 200 20 0 0 <def.center><def.bfont_white>Aileniz yıkılsın mı?<def.centere>
dhtmlgump 42 120 60 20 0 0 <def.bfont_white>Evet
button 40 140 4005 4007 1 0 1
dhtmlgump 142 120 60 20 0 0 <def.bfont_white>Hayır
button 140 140 4017 4019 1 0 0
[dialog d_ailesistemi_aileyik button]
on=1
if (<cont.type>==t_eq_trade_window)
return 1
elif !(<src.restest 1 i_ailesistemi_aileyikdeed>)
src.smx Üzerinizde bir aile yıkma belgesi bulunmuyor..
return 1
endif
if !(<src.tag0.ailesistemi_reisimben>)
src.smx Bir aileniz yok, aile yıkabilmek için öncelikle bir aileniz olmalı..
else
local.lastobj=<obj>
while (<var0.__ailesistemi_aile_<src.tag.ailesistemi_soyadim>_uye<dlocal.s>>)
obj=<var.__ailesistemi_aile_<src.tag.ailesistemi_soyadim>_uye<dlocal.s>>
obj.tag.ailesistemi_ailemvar
obj.tag.ailesistemi_soyadim
obj.soyadsil
var.__ailesistemi_aile_<src.tag.ailesistemi_soyadim>_uye<dlocal.s>
local.s ++
endwhile
serv.allclients smg <src.tag.ailesistemi_soyadim> adlı aile <src.name> adlı reisi tarafından dağıtılmıştır..
var.__ailesistemi_aile_<src.tag.ailesistemi_soyadim>
src.tag.ailesistemi_ailemvar
src.tag.ailesistemi_soyadim
src.tag.ailesistemi_reisimben
src.soyadsil
src.consume 1 i_ailesistemi_aileyikdeed
obj=<local.lastobj>
endif
[function f_ailesistemi_ailedenadamat]
local.aile <argv[0]>
local.lastobj=<obj>
obj=<argv[1]>
while !(<var0.__ailesistemi_aile_<local.aile>_uye<dlocal.s>>==<obj.uid>)
local.s ++
if (<local.s> > 100)
src.smx Hata: Önemli bir hata oluştu, bunu aile adıyla birlikte forumlarda bana özel mesaj atın..
return 1
endif
endwhile
if (<var0.__ailesistemi_aile_<local.aile>_uye<eval <local.s>+1>>)
while (<var0.__ailesistemi_aile_<local.aile>_uye<eval <local.s>+1>>)
var0.__ailesistemi_aile_<local.aile>_uye<dlocal.s> <var.__ailesistemi_aile_<local.aile>_uye<eval <local.s>+1>>
local.s ++
endwhile
var.__ailesistemi_aile_<local.aile>_uye<dlocal.s>
else
var.__ailesistemi_aile_<local.aile>_uye<dlocal.s>
endif
obj.tag.ailesistemi_ailemvar
obj.tag.ailesistemi_soyadim
obj.soyadsil
obj=<local.lastobj>
//********************************************************************************
[plevel 7]
f__ailelerisil
[function f__ailelerisil]
if (strcmp('<src.account.name>','uodev'))
return 1
endif
src.__allplayerchars __f_ailelerisil
[function __f_ailelerisil]
if (<tag0.ailesistemi_reisimben>)
newgold 550000
local.lastobj=<obj>
while (<var0.__ailesistemi_aile_<tag.ailesistemi_soyadim>_uye<dlocal.s>>)
obj=<var.__ailesistemi_aile_<tag.ailesistemi_soyadim>_uye<dlocal.s>>
obj.tag.ailesistemi_ailemvar
obj.tag.ailesistemi_soyadim
obj.newgold <def.ailesistemi_ailegirisucreti>
local.s ++
endwhile
for x 1 100
var.__ailesistemi_aile_<tag.ailesistemi_soyadim>_uye<dlocal.x>
endfor
var.__ailesistemi_aile_<tag.ailesistemi_soyadim>
tag.ailesistemi_ailemvar
tag.ailesistemi_soyadim
tag.ailesistemi_reisimben
obj=<local.lastobj>
endif
soyadsil
//********************************************************************************
[function soyadsil]
name <strarg <name>>
[function f_ailesistemi_elle_aileyik]
if !(<var0.__ailesistemi_aile_<args>>)
src.smx Bu isimde bir aile yok..
return 1
endif
var.__ailesistemi_aile_<args>
for x 1 100
var.__ailesistemi_aile_<args>_uye<dlocal.x>
endfor
__allplayerchars __f_ailesistemi_elle_aileyik <args>
[function __f_ailesistemi_elle_aileyik]
if !(strcmpi('<streat <name>>','<args>'))
tag.ailesistemi_ailemvar
tag.ailesistemi_soyadim
tag.ailesistemi_reisimben
name <strarg <name>>
endif
[function f_ailesistemi_bosluksuzisim]
return <strarg <args>>
[EOF]
.var.theme1 3000.var.theme2 9300|
|
| Konu | Kategori | Son cevap | Son yazan | Mesaj | Görüntüleme | |
|---|---|---|---|---|---|---|
|
Ultima Online Anketi
Son cevap: 01-08 15:05 · Son yazan: gizemli · Mesaj: 13 · Görüntü: 9500
|
Ultima Online Genel | 01-08 15:05 | gizemli |
13 | 9500 |
|
|
Sunucunuza özel web tasarım, hosting ve scripting
Son cevap: 03-04 15:02 · Son yazan: riot · Mesaj: 1 · Görüntü: 3179
|
Garbage | 03-04 15:02 | riot |
1 | 3179 |
|
Scripting için yardımcı arıyorum
Son cevap: 02-09 22:53 · Son yazan: asaga0909 · Mesaj: 1 · Görüntü: 3422
|
Sarı Sayfalar | 02-09 22:53 | asaga0909 |
1 | 3422 |
|
Scripting öğrenmek istiyorum
Son cevap: 27-04 13:32 · Son yazan: Readher · Mesaj: 9 · Görüntü: 9101
|
Sarı Sayfalar | 27-04 13:32 | Readher |
9 | 9101 |
|
Kontakt 5 Kısa hikaye yarışması
Son cevap: 28-08 21:13 · Son yazan: Deidara · Mesaj: 1 · Görüntü: 4389
|
Role Play | 28-08 21:13 | Deidara |
1 | 4389 |