// -------------------------------------------------------

// -- Script Adı	   : Page Sistemi       	--

// -- Scripti Yazan	   : Slothere			--

// -- En Son Düzenleyen	   : Potenza	        --

// -- Son Düzenleme Tarihi : 10.Haziran.2009		        --

// -------------------------------------------------------



[EVENTS e_send]

on=@LOGIN

SDIALOG d_page_answer

EVENTS -e_send



[PLEVEL 2]

pg



[FUNCTION pg]

IF (<serv.gmpages>)

sdialog d_page_view

else

src.sysmessage @38,,1 Page bulunmuyor..

return 1

ENDIF



[DIALOG d_page_send]

0,400



PAGE 0

nomove

resizepic 30 30 5120 700 120

resizepic 40 40 3000 670 90

///checkertrans 40 40 480 100

resizepic 70 60 3000 620 35

dcroppedtext 70 40 400 20 920 Lütfen sorununuzu kısaca ve net olarak belirtiniz.

dtextentry 75 65 600 20 920 1

dtext 100 100 920 Gönder

button 80 100 2714 2715 1 0 1



[DIALOG d_page_send button]

on=1

GMPAGE add <uid> <argtxt[1]>

src.sysmessage @58,,1 Mesajınız iletildi, <serv.gmpages>. sıradasınız.

if !(<dvar.staff> >= 1)

src.sysmessage @38,,1 Aktif yetkili bulunmadığı için mesajınıza geç yanıt gelebilir.

endif



[DIALOG d_page_view]

0,0



PAGE 0

nomove

resizepic 0 50 5120 650 300

resizepic 10 60 3000 620 270

//////checkertrans 10 60 630 280

dtext 55 60 025 Gönderen

dtext 195 60 025 Gönderilen

dtext 350 60 025 Süre

dtext 450 60 025 Durum

button 20 305 4006 4007 1 0 20000

dtext 50 305 920 Hepsini Sil

local.page = 1

local.bildiri = 0



PAGE 1

FOR 0 <eval (<serv.gmpages>)-1>

IF (<dlocal.bildiri> > 10)

local.bildiri = 0

button 610 320 015e1 015e5 0 <eval (<dlocal.page>)+1> 1

local.page += 1

PAGE <dlocal.page>

button 580 320 015e3 015e7 0 <eval (<dlocal.page>)-1> 1

ENDIF

resizepic 55 <eval (<dlocal.bildiri>*20)+80> 3000 140 20

dcroppedtext 60 <eval (<dlocal.bildiri>*20)+80> 135 20 <QVAL (<uid.<strarg <serv.gmpage.<dlocal._for>.reason>>.isonline>)? 040:025> <uid.<strarg <serv.gmpage.<dlocal._for>.reason>>.name>

resizepic 195 <eval (<dlocal.bildiri>*20)+80> 3000 155 20

dcroppedtext 200 <eval (<dlocal.bildiri>*20)+80> 145 20 920 <streat <serv.gmpage.<dlocal._for>.reason>>

resizepic 350 <eval (<dlocal.bildiri>*20)+80> 3000 100 20

dcroppedtext 355 <eval (<dlocal.bildiri>*20)+80> 95 20 920 <eval (<serv.gmpage.<dlocal._for>.time>)/60> dk önce

resizepic 450 <eval (<dlocal.bildiri>*20)+80> 3000 180 20

dcroppedtext 455 <eval (<dlocal.bildiri>*20)+80> 175 20 920 <QVAL (<serv.gmpage.<dlocal._for>.handled>)? İlgileniliyor (<uid.<serv.gmpage.<dlocal._for>.handled>.name>):Beklemede>

button 20 <eval (<dlocal.bildiri>*20)+80> 4006 4007 1 0 <eval (<dlocal._for>)+1>

local.bildiri +=1

ENDFOR



[DIALOG d_page_view BUTTON]

ON = 1 1000

IF (<serv.gmpage.<eval <argn>-1>.handled>) && (<uid.<serv.gmpage.<eval <argn>-1>.handled>> != <src.uid>)

src.sysmessage @38,,1 Bu bildiriyle <uid.<serv.gmpage.<eval <argn>-1>.handled>.name> ilgileniyor.

return 1

ENDIF

src.ctag.sira = <eval <argn>-1>

sdialog d_page_info

return 1



on=20000

IF (<ispghandled>)

src.sysmessage @38,,1 Şu anda ilgilenilen bildiriler var..

return 1

ELSE

PAGE WIPE

serv.allclients sysmessage @07a1,,1 Tüm pageler silinmiştir.

ENDIF



[DIALOG d_page_info]

0,0



PAGE 0

resizepic 100 50 5120 300 330

resizepic 110 60 3000 270 300

///checkertrans 110 60 280 310

dtext 120 70 025 Gönderenin;

dtext 120 210 025 Gönderilen;

dhtmlgump 120 100 200 105 0 0 <def.bfont_white>Account: <uid.<strarg <serv.gmpage.<src.ctag0.sira>.reason>>.account><def.br>Ismi: <uid.<strarg <serv.gmpage.<src.ctag0.sira>.reason>>.name><def.br>SkillTotal <fval <uid.<strarg <serv.gmpage.<src.ctag0.sira>.reason>>.skilltotal>><def.br>StatTotal: <eval (<uid.<strarg <serv.gmpage.<src.ctag0.sira>.reason>>.str>)+(<uid.<strarg <serv.gmpage.<src.ctag0.sira>.reason>>.dex>)+(<uid.<strarg <serv.gmpage.<src.ctag0.sira>.reason>>.int>)><def.br>Kayit: <uid.<strarg <serv.gmpage.<src.ctag0.sira>.reason>>.account.firstconnectdate><def.br>IP: <uid.<strarg <serv.gmpage.<src.ctag0.sira>.reason>>.account.lastip>

dhtmlgump 120 230 225 110 1 1 <streat <serv.gmpage.<src.ctag0.sira>.reason>>



resizepic 100 380 5120 300 170

resizepic 110 390 3000 270 140

///checkertrans 110 390 280 130

FOR 6

button 120 <eval (<dlocal._for>*20)+380> 4006 4007 1 0 <dlocal._for>

ENDFOR

dtext 160 400 07a1 Sil

dtext 160 420 07a1 Cevap Gönder

dtext 160 440 07a1 Yanına Getir

dtext 160 460 07a1 Yanına Git

dtext 160 480 07a1 Hapise Gönder [Hatalı Page]

dtext 160 500 07a1 Page Cezası

dtext 320 500 07a1 saat



resizepic 250 500 3000 60 20

dtextentry 255 500 50 35 07a1 99 1



[DIALOG d_page_info BUTTON]

on = 1

IF (<serv.gmpage.<src.ctag0.sira>.handled>) && (<uid.<serv.gmpage.<src.ctag0.sira>.handled>> != <src.uid>)

src.sysmessage @38,,1 Şu anda bu bildiri ile ilgileniliyor. (<uid.<serv.gmpage.<src.ctag0.sira>.handled>.name>)

return 1

ENDIF

TRY gmpage.<eval <src.ctag0.sira>>.handle

TRY gmpage.<eval <src.ctag0.sira>>.d

src.sysmessage @07a1,,1 Page silindi.



on=2

IF (<serv.gmpage.<src.ctag0.sira>.handled>) && (<uid.<serv.gmpage.<src.ctag0.sira>.handled>> != <src.uid>)

src.sysmessage @38,,1 Şu anda bu bildiri ile ilgileniliyor. (<uid.<serv.gmpage.<src.ctag0.sira>.handled>.name>)

return 1

ENDIF

TRY gmpage.<eval <src.ctag0.sira>>.handle

ref1 = <strarg <serv.gmpage.<src.ctag0.sira>.reason>>

ref1.sdialog d_send_reply



on=3

IF (<serv.gmpage.<src.ctag0.sira>.handled>) && (<uid.<serv.gmpage.<src.ctag0.sira>.handled>> != <src.uid>)

src.sysmessage @38,,1 Şu anda bu bildiri ile ilgileniliyor. (<uid.<serv.gmpage.<src.ctag0.sira>.handled>.name>)



return 1

ENDIF

ref1 = <strarg <serv.gmpage.<src.ctag0.sira>.reason>>

IF (<ref1.isonline>)

TRY gmpage.<eval <src.tag0.sira>>.handle

ref1.summonto

ELSE

src.sysmessage @38,,1 <ref1.name> şu anda oyunda değil..

return 1

ENDIF



on=4

IF (<serv.gmpage.<src.ctag0.sira>.handled>) && (<uid.<serv.gmpage.<src.ctag0.sira>.handled>> != <src.uid>)

src.sysmessage @38,,1 Şu anda bu bildiri ile ilgileniliyor. (<uid.<serv.gmpage.<src.ctag0.sira>.handled>.name>)

return 1

ENDIF

ref1 = <strarg <serv.gmpage.<src.ctag0.sira>.reason>>

IF (<ref1.isonline>)

TRY gmpage.<eval <src.tag0.sira>>.handle

src.go <ref1.p>

ELSE

src.sysmessage @38,,1 <ref1.name> şu anda oyunda değil..

return 1

ENDIF



on=5

ref1 = <strarg <serv.gmpage.<src.ctag0.sira>.reason>>

if (<ref1.account.plevel> > 1)

src.sysmessage @38,,1 Yetkilileri cezalandıramazsınız.

return 1

endif

if (<ref1.isevent.e_jaevent>)

src.sysmessage @38,,1 '<ref1.name>' adlı oyuncu zaten cezalandırılmış.

return 1

endif

ref1.tag.cezaneden Hatalı Page

ref1.tag.cezaveren <src.uid>

serv.allclients stafftrig2 <src.name> adlı yetkili '<ref1.name>' adlı şahısı <def.ceza4> suçundan cezalandırdı.

ref1.tag.ceza4lvl <eval <ref1.tag0.ceza4lvl>+1>

trysrc <ref1> src.newitem i_jailcik

trysrc <ref1> new.equip

trysrc <ref1> new.timer <eval (<def.ceza4sure>*<ref1.dtag0.ceza4lvl>)>

ref1.go jail4

ref1.events +e_jaevent

ref1.tag.ceza 4

TRY gmpage.<eval <src.ctag0.sira>>.handle

TRY gmpage.<eval <src.ctag0.sira>>.d



on=6

ref1 = <strarg <serv.gmpage.<src.ctag0.sira>.reason>>

if (<ref1.account.plevel> > 1)

src.sysmessage @38,,1 Yetkilileri cezalandıramazsınız.

return 1

endif

if (<ref1.findid.i_pageban>)

src.sysmessage @38,,1 '<ref1.name>' adlı oyuncunun page atamama cezası bulunuyor.

return 1

endif

serv.allclients stafftrig2 <src.name> adlı yetkili '<ref1.name>' adlı şahısa <argtxt[99]> saat page atamama cezası verdi.

ref1.sysmessage @38,,1 <argtxt[99]> saat boyunca page atamıcaksınız.

trysrc <ref1> src.newitem i_pageban

trysrc <ref1> new.equip

trysrc <ref1> new.timer <eval (<argtxt[99]>)*3600>

ref1.tag.pageban 1

TRY gmpage.<eval <src.ctag0.sira>>.handle

TRY gmpage.<eval <src.ctag0.sira>>.d



[DIALOG d_send_reply]

0,0



PAGE 0

nomove

resizepic 30 30 5120 500 250

resizepic 40 40 3000 470 220

///checkertrans 40 40 480 230

resizepic 70 170 3000 420 50

dcroppedtext 70 150 400 20 920 <uid.<strarg <serv.gmpage.<src.ctag0.sira>.reason>>.name> isimli kişiye gönderilecek iletiyi yazınız.

dtextentry 75 175 400 45 920 1

dtext 100 230 920 Gönder

button 80 230 2714 2715 1 0 1

dtext 70 40 920 Gönderilen İleti,

dhtmlgump 70 65 420 65 1 1 <streat <serv.gmpage.<src.ctag0.sira>.reason>>



[DIALOG d_send_reply BUTTON]

on=1

tag.pagemsg = <argtxt[1]>

tag.date = <serv.rtime>

tag.sender = <src.uid>

tag.sended = <streat <serv.gmpage.<src.ctag0.sira>.reason>>

IF (<ISONLINE>)

TRYSRC <UID> sdialog d_page_answer

src.page d

ELSE

events +e_send

src.page d

ENDIF

src.sysmessage @07a1,,1 Cevap gönderildi.

return 1



[DIALOG d_page_answer]

0,0



PAGE 1

button 15 30 30 30 0 2 1

dtext 15 60 07a1 Mesajınız Var!



PAGE 2

resizepic 30 30 5120 500 300

resizepic 40 40 3000 470 270

///checkertrans 40 40 480 280

dtext 70 60 07a1 Mesajı Gönderen: <uid.<tag0.sender>.name> | Tarih: <tag0.date>

dhtmlgump 70 85 400 90 1 1 <tag0.pagemsg>

dtext 70 180 07a1 Gönderdiğiniz İleti,

dhtmlgump 70 205 400 70 1 1 <tag0.sended>



[DIALOG d_page_answer BUTTON]

on=0

tag.sended =

tag.sender =

tag.pagemsg =

tag.date =



[FUNCTION ispghandled]

FOR 0 <eval (<serv.clients>-1>

IF (<serv.client.<dlocal._for>.account.plevel> > 1) && (<serv.gmpage.<dlocal._for>.handled>)

return 1

ENDIF

ENDFOR

return 0



//////////////////////---Page Ceza---/////////////////////////



[function pageceza]

src.sdialog d_pageceza



[function f_cezaver]

if (<argo.tag0.pageban> == 1)

src.sysmessage @38,,1 <argo.name> adlı oyuncunun page cezası zaten var.

return 1

elseif (<argo.account.plevel> >= 2)

src.sysmessage @38,,1 Yetkilileri cezalandıramazsınız.

return 1

else

argo.tag.pageban=1

argo.newitem i_pageban

argo.act.timer <src.ctag.cezasurever>

argo.act.cont=<argo.uid>

src.sysmessage @58,,1 <argo.name> adlı oyuncuya <eval (<argo.findid.i_pageban.timer>/3600)> saat page atamama cezası verdiniz.

argo.sysmessage @38,,1 <eval (<argo.findid.i_pageban.timer>/3600)> saat boyunca page atamıcaksınız.

endif



[function f_cezaaf]

if !(<argo.tag0.pageban> == 1)

src.sysmessage @38,,1 <argo.name> adlı oyuncunun page cezası bulunmuyor.

return 1

else

argo.tag.pageban=0

argo.findid.i_pageban.remove

src.sysmessage @58,,1 <argo.name> adlı oyuncunun page atamama yasağı kaldırıldı.

argo.sysmessage @68,,1 Page yasağınız <src.name> tarafından kaldırıldı.

endif



[DIALOG d_pageceza]

100, 100

nomove

PAGE 0

resizepic 0 0 5120 300 300

resizepic 10 10 300 270 270

dtext 90 8 38 Page Ceza Sistemi

dtext 70 50 07a1 1 Saat

dtext 70 70 07a1 2 Saat

dtext 70 90 07a1 3 Saat

dtext 70 110 07a1 4 Saat

dtext 70 130 07a1 5 Saat

dtext 70 150 07a1 1 Gün

dtext 70 170 07a1 Yasağı Kaldır

button 38 50 4006 4005 1 0 1

button 38 70 4006 4005 1 0 2

button 38 90 4006 4005 1 0 3

button 38 110 4006 4005 1 0 4

button 38 130 4006 4005 1 0 5

button 38 150 4006 4005 1 0 6

button 38 170 4006 4005 1 0 7



[DIALOG d_pageceza button]

on=0

return 1



on=1

src.sysmessage @58,,1 Kimi cezalandırmak istiyorsunuz?

src.ctag.cezasurever 3600

src.targetf f_cezaver



on=2

src.sysmessage @58,,1 Kimi cezalandırmak istiyorsunuz?

src.ctag.cezasurever 7200

src.targetf f_cezaver



on=3

src.sysmessage @58,,1 Kimi cezalandırmak istiyorsunuz?

src.ctag.cezasurever 14400

src.targetf f_cezaver



on=4

src.sysmessage @58,,1 Kimi cezalandırmak istiyorsunuz?

src.ctag.cezasurever 18000

src.targetf f_cezaver



on=5

src.sysmessage @58,,1 Kimi cezalandırmak istiyorsunuz?

src.ctag.cezasurever 21600

src.targetf f_cezaver



on=6

src.sysmessage @58,,1 Kimi cezalandırmak istiyorsunuz?

src.ctag.cezasurever 60*60*24*1

src.targetf f_cezaver



on=7

src.sysmessage @38,,1 Kimin cezasını kaldırmak istiyorsunuz?

src.targetf f_cezaaf



[ITEMDEF i_pageban]

id=i_memory

name=page ban timer

type=t_eq_script



on=@Create

attr attr_newbie|attr_invis

timer 259200



ON=@Timer

cont.tag.pageban=0

cont.sysmessage @68,,1 Page cezanızın süresi doldu.Artık yetkili çağrısı yapabilirsiniz.

attr attr_can_decay

remove



[EOF]