Axuare -  01-08-2012 03:33
Açıklama :
Slothere'nin reagent scriptiydi.Benimde aklımda böyle birşey vardı mantıken aynı reagent gibi sadece bir kaç ekleme yapıldı.Madenlerin her yerine banker koyulamayacagı ve madenciler düşünülerekten karşınızda miner cart. // Slothereye teşekkürler.

Kod:
[itemdef i_miner_cart]
id=01a88
name=miner cart
value=2900
weight=3
type=t_script

on=@create
attr 010
color 00

on=@dclick
if (<distance> > 1)
src.hata Miner carta yetişemiyorsunuz.
return 1
endif

if !(<more1>)
more1 <src.uid>
src.okey Miner cart artık size ait.
elseif (<more1> != <src.uid>)
src.hata Bu miner cart size ait değil.
return 1
endif

if (<src.flags>&statf_dead|statf_freeze|statf_stone)
src.hata Şu anki durumunuzda kullanamazsınız.
return 1
else
sdialog d_miner_cart
return 1
endif
endif

on=@targon_char
target @38,,1 Sadece ingot ekleyebilirsiniz.
return 1

on=@targon_item
if (<src.targ.topobj> != <src>)
target @38,,1 Sadece üzerinizdeki ingotları ekleyebilirsiniz.
elif (<src.targ.type> != t_ingot)
target @38,,1 Sadece ingot ekleyebilirsiniz.
elif !(<src.targ.amount>) || !(<src.targ.normingot>)
target @38,,1 Bu ingotu ekleyemezsiniz.
else
try tag0.<src.targ.baseid>=<eval (<tag0.<src.targ.baseid>>+<src.targ.amount>)>
src.okey <src.targ.amount> adet <src.targ.name> eklediniz.
src.targ.remove
sdialog d_miner_cart
endif
return 1

[dialog d_miner_cart]
0,0
nomove
resizepic 30 30 3000 530 400
resizepic 50 50 9300 490 360

dorigin 70 70

for 0 12
dtext +50 *20 <qval(<isempty <tag.<miner_cart <dlocal._for>>>>)?0:0480> <serv.itemdef.<miner_cart <dlocal._for>>.name> (<dtag0.<miner_cart <dlocal._for>>>)
tilepic +25 +2 <serv.itemdef.<miner_cart <dlocal._for>>.id>
if !(<isempty <tag.<miner_cart <dlocal._for>>>>)
checkbox +5 +2 56 55 0 <dlocal._for>
endif
endfor

dtext 70 350 0c1 Adet:
resizepic 68 370 2620 50 30
dtextentry 85 375 40 20 1153 0 0
dtext 120  375 0c1 Ingot cıkart.
button 220 375 247 248 1 0 13

button 305 160 55 56 1 0 10
dtext 330 159 1153 Ekle
button 305 180 55 56 1 0 11
dtext 330 179 1153 Tümünü Ekle
button 305 200 55 56 1 0 12
dtext 330 199 1153 Tümünü Çıkart
button 305 220 55 56 1 0 14
dtext 330 220 37 Miner Cartı Kaldır.
dtext 320 250 1153 [Not:Miner cartı kaldırdıgınız
dtext 320 265 1153 zaman içinde bulunan ingotlar
dtext 320 284 37 SİLİNİR
dtext 390 284 1153 ]

[dialog d_miner_cart button]
on=0
src.okey Miner cart menüsünü kapattınız.
return 1

on=10
target @1001,1,1 Eklemek istediğiniz ingotu seçiniz.
return 1

on=11
ref1=<uid>
forcont <src.findlayer(layer_pack)> 0
if (<type> == t_ingot) && (<normingot>)
ref1.tag0.<baseid>=<eval (<ref1.tag0.<baseid>>+<amount>)>
src.okey <amount> adet <name> eklendi.
remove
endif
endfor
sdialog d_miner_cart

on=12
ref1=<uid>
for 0 13
if !(<isempty <ref1.tag.<miner_cart <dlocal._for>>>>)
serv.newitem <miner_cart <dlocal._for>>,<ref1.dtag0.<miner_cart <dlocal._for>>>,<src.findlayer(layer_pack)>
new.contp 50,50
src.okey <ref1.dtag0.<miner_cart <dlocal._for>>> adet <serv.itemdef.<miner_cart <dlocal._for>>.name> çıkartıldı.
ref1.tag0.<miner_cart <dlocal._for>>=
endif
endfor

on=13
if !(<isnum <argtxt[0]>>)
src.hata Sadece rakam girebilirsiniz.
elif (<dargtxt[0]> > 250)
src.hata Bir seferde en fazla 250 adet ingot çıkartabilirsiniz.
elif (<argtxt[0]> <= 0)
src.hata Hatalı adet girdiniz.
else
for 0 13
if (<argchk[<dlocal._for>]> == 1)
if (<dtag0.<miner_cart <dlocal._for>>> < <dargtxt[0]>)
src.hata Belirttiğiniz miktarda <serv.itemdef.<miner_cart <dlocal._for>>.name> bulunmuyor.
elif (<argtxt[0]> <= 0) || !(<isnum <argtxt[0]>>)
src.hata Hatalı adet girdiniz.
return 1
else
serv.newitem <miner_cart <dlocal._for>>,<dargtxt[0]>,<src.findlayer(layer_pack)>
src.okey <dargtxt[0]> adet <serv.itemdef.<miner_cart <dlocal._for>>.name> çıkarttınız.
try tag0.<miner_cart <dlocal._for>>=<eval (<dtag0.<miner_cart <dlocal._for>>>-<dargtxt[0]>)>
endif
endif
endfor
endif
sdialog d_miner_cart

on=14
serv.newitem i_deed,1,<src.uid>
new.more1 = <baseid>
new.attr=attr_newbie
new.name deed to <name>
ref1 = <uid>
forinstances i_miner_cart
if (<link.uid>==<ref1.uid>)
remove
endif
endfor
remove
src.okey Miner cartı başarılı bir şekilde kaldırdınız.
endif

[function miner_cart]
doswitch <dargn>
return i_ingot_iron
return i_ingot_dull_copper
return i_ingot_copper
return i_ingot_bronze
return i_ingot_gold
return i_ingot_shadow
return i_ingot_silver
return i_ingot_agapite
return i_ingot_verite
return i_ingot_mytheril
return i_ingot_valorite
return i_ingot_blackrock
return i_ingot_bloodrock
enddo

[function normingot]
if ((<baseid> == i_ingot_iron) || (<baseid> == i_ingot_dull_copper) || (<baseid> == i_ingot_copper) || (<baseid> == i_ingot_gold) || (<baseid> == i_ingot_bronze) || (<baseid> == i_ingot_shadow) || (<baseid> == i_ingot_silver) || (<baseid> == i_ingot_agapite) || (<baseid> == i_ingot_verite) || (<baseid> == i_ingot_mytheril) || (<baseid> == i_ingot_valorite) || (<baseid> == i_ingot_blackrock) || (<baseid> == i_ingot_bloodrock))
return 1
else
return 0
endif

[EOF]

YORUMLAR (0)

Henüz yorum yapılmamış.

BENZER SAYFALAR