stylez :
Kod:
act.newitem i_gold,50000,<act>,1
bu şekilde denermisin ve return çektirtme
Teşekkürler bu şekilde çalıştı.
Bu arada olayın tamamı bu ihtiyaç duyan yada fikir almak isteyenler için. Denedim çalışıyor. Okuyabildiğim kadarıyla diğer scp lerden ve siteden fikir alarak böyle basit birşey yazdım. Eksiklerim yada gereksiz kullanımlarım vardır fikirlere açığım.
Kod:
[chardef c_h_minoc_tuccar]// minoca koyulacak
defname c_h_minoc_tuccar
id c_man
NAME=#NAMES_HUMANMALE
DESIRES=i_gold,e_notoriety
AVERSIONS=t_TRAP,t_eerie_stuff
TEVENTS=e_tuccar_1
CATEGORY=Civilized
SUBSECTION=Tradesmen
DESCRIPTION=Tuccar
ON=@Create
COLOR=colors_skin
STR={71 85}
DEX=0
INT={66 80}
FLAGS=01
ITEMID={50.0 70.0}
ITEMNEWBIE=random_male_hair
COLOR=0455
ON=@npcrestock///kıyafet değiştir
ITEM=i_shroud
COLOR=07a1
ATTR=04
ITEM=i_leather_gloves
COLOR=0455
ATTR=04
ITEM=i_leather_gorget
COLOR=0455
ATTR=04
ITEM=i_boots_calf
COLOR=0455
ATTR=04
ON=@Click
message @64,,1 [<serv.name> Tüccar]
message @0835,,1 <name>
return 1
ON=@Dclick
if (<src.account.plevel> > 1) && (<src.account.plevel> < 7)
src.SYS_KIRMIZI Bunu yapamazsınız.
return 1
else
sdialog d_tuccar1
return 1
endif
[chardef c_h_brit_tuccar]// varış npc
defname c_h_brit_tuccar
id c_man
NAME=#NAMES_HUMANMALE
DESIRES=i_gold,e_notoriety
AVERSIONS=t_TRAP,t_eerie_stuff
CATEGORY=Civilized
SUBSECTION=Tradesmen
DESCRIPTION=Tuccar
ON=@Create
COLOR=colors_skin
STR={71 85}
DEX=0
INT={66 80}
FLAGS=01
ITEMID={50.0 70.0}
ITEMNEWBIE=random_male_hair
COLOR=0455
ON=@npcrestock///kıyafetleri değiştir
ITEM=i_shroud
COLOR=07a1
ATTR=04
ITEM=i_leather_gloves
COLOR=0455
ATTR=04
ITEM=i_leather_gorget
COLOR=0455
ATTR=04
ITEM=i_boots_calf
COLOR=0455
ATTR=04
ON=@Click
message @64,,1 [<serv.name> Savaşçı]
message @0835,,1 <name>
return 1
ON=@Dclick
if (<src.isevent.e_tuccar_gorev>)
message @0835,,1 Teşekkürler işte ödülün.
salute
src.events -e_tuccar_gorev
src.findid.i_tuccar_torba.remove
src.findid.i_tuccar_sure.remove
src.newitem i_gold,(50000)
SRC.ACT.BOUNCE
src.newitem i_gold,(50000)
SRC.ACT.BOUNCE
src.newitem i_gold,(50000)
SRC.ACT.BOUNCE
//sdialog d_tuccar2
return 1
endif
///////////dialoglar////////////
///////////vendor dialog/////////////
[DIALOG d_tuccar1]/// görev tanım
0, 0
RESIZEPIC 150 150 5170 220 270 // d_tuccar1
DTEXT 220 175 1153 Tüccar Görevi // tuccar_menu_baslik
DTEXT 185 190 0 <src.name> Britain'de ki // Tanim
DTEXT 175 205 0 savaşçıların bu malzemelere // tanim_2
DTEXT 175 220 0 ihtiyacı var. Senden istediğim // tanim_3
DTEXT 175 235 0 kabul edersen 100.000 altın // tanim_4
DTEXT 175 250 0 para karşılığında malzemeleri // tanim_5
DTEXT 175 265 0 30dk içinde teslim etmendir. // tanim_6
DTEXT 175 280 0 Tabi senden 50.000 teminat // tanim_7
DTEXT 175 295 0 almam gerekiyor. Merak etme // tanim_8
DTEXT 175 310 0 teminatı malzemeleri teslim // tanim_9
DTEXT 175 325 0 edince geri alacaksın. // tanim_9
TILEPICHUE 250 206 0e76 1266 // tilepic_2
BUTTON 175 370 2117 2118 1 0 1 // kabul_et
DTEXT 190 368 0 Kabul Et // kabulet_text
BUTTON 290 370 2117 2118 1 0 2 // redd_et
DTEXT 306 368 0 Reddet // reddet_text
[DIALOG d_tuccar1 BUTTON]
On=0
src.SYS_BEYAZ Kapattınız.
return 1
On=1 // kabul_et
if (<distance> > 3)
src.SYS_KIRMIZI Tüccara yeterince yakın değilsiniz.
return 1
elif (<src.isevent.e_tuccar_gorev>)
src.SYS_KIRMIZI Tamamlanmamış görevin bulunmakta tamamla yada iptal et.
return 1
elif !(<src.restest 50000 i_gold>)
src.SYS_KIRMIZI Teminat olarak ödemek için çantanızda 50.000 altın paranız bulunmamaktadır.
else
src.consume 50000 i_gold
src.SYS_BEYAZ Görevi kabul ettiniz.
serv.allclients sysmessage @54,,1 <src.name> isimli oyuncu <src.region.name> civarında tüccar görevine başlamıştır.
src.events e_tuccar_gorev
src.newitem i_tuccar_torba
src.act.bounce
src.newitem i_tuccar_sure
new.equip
endif
On=2 // redd_et
src.SYS_BEYAZ Kabul etmediniz.
return 1
//////////////item dialog////////////
[DIALOG d_gorev_torba]/// torba menü
0, 0
noclose
RESIZEPIC 200 200 5170 320 150 // d_gorev_torba
DTEXT 320 225 1153 -Tüccar Görevi- // baslık
DTEXT 230 250 89 Göreviniz: // Gorev_baslık
DTEXT 300 250 0 Size verilen malzemeleri en kısa // Gorev_tanımı
DTEXT 230 265 0 sürede Britteki alıcıya teslim etmektir. // gorev_tanımı_2
BUTTON 230 295 2117 2118 1 0 1 // Devam_et
DTEXT 247 293 70 Göreve devam // Devam_et_text
BUTTON 389 295 2117 2118 1 0 2 // Görev_iptal
DTEXT 405 293 34 Görevi iptal et // Görev_iptal_text
[DIALOG d_gorev_torba BUTTON]
On=1 // Devam_et
src.SYS_BEYAZ Göreviniz devam ediyor.
return 1
On=2 // Görev_iptal teminat yandı
src.events -e_tuccar_gorev
src.findid.i_tuccar_torba.remove
src.findid.i_tuccar_sure.remove
src.SYS_BEYAZ Görevi iptal ettiniz.
return 1
//////////////eşyalar////////////////
[itemdef i_tuccar_torba]
DEFNAME=i_tuccar_torba
NAME=Tuccar Gorev
id=i_bag
TYPE=t_script
WEIGHT=1
CATEGORY=Sistem Esyasi
SUBSECTION=Tuccar Sistemi
DESCRIPTION=Gorev
ON=@CREATE
COLOR=04f2
attr attr_static|ATTR_MOVE_NEVER
on=@click
message @07a1,,1 Tüccar Görevi
message @07a1,,1 Malzeme
src.SYS_BEYAZ Görev bilgileri veya görev iptaline ulaşmak için çift tıklayınız.
return 1
on=@dclick
if (<src.isevent.e_tuccar_gorev>)
sdialog d_gorev_torba
else
remove
return 1
endif
[itemdef i_tuccar_sure]///30dk da yetiştirsin fazla fazla zaman ölmezse tabi
id=i_memory
name=tuccar sure
type=t_eq_script
ON=@EQUIP
TIMER=1800
ATTR=attr_decay //| attr_invis
on=@timer
cont.say @026,,1 Süren doldu!
cont.message @026,,1 Malzemeleri zamanında yetiştiremedin!
cont.events -e_tuccar_gorev
cont.findid.i_tuccar_torba.remove
remove
////////////////events//////////////
[events e_tuccar_1] /// npc oyunculara sataşsın :)
On=@NPCSeeNewPlayer
salute
SAY @026,,1 Hey sen bak hele!
salute
SAY @026,,1 Tam sana göre bir görevim var.
[events e_tuccar_gorev]
On=@Itemdclick
if (<act.baseid> == i_runebook) || (<act.baseid> == i_moon_gate)///kestirme yapmasın diye
src.SYS_KIRMIZI Görev sırasında kullanamazsınız.
return 1
endif
On=@SkillStart
if (<action> == id(skill_stealth)) || (<action> == skill_stealth) || ((<action> == id(skill_snooping)) || (<action> == skill_snooping)) || ((<action> == id(skill_stealing)) || (<action> == skill_stealing)) || ((<action> == id(skill_hiding)) || (<action> == skill_hiding))
src.SYS_KIRMIZI Görev sırasında kullanamazsınız.
return 1
endif
On=@Death///görev sahibi ölürse
act.SYS_BEYAZ <src.name> isimli tüccar görevi yapan kişiyi öldürdün. Malzemelerin karaborsa ederi 50.000 altın para çantana aktarıldı.
act.newitem i_gold,50000,<act>,1 //// görev sahibini öldürene
src.SYS_KIRMIZI Öldün ve malzemeler çalındı.
src.events -e_tuccar_gorev
src.findid.i_tuccar_torba.remove
src.findid.i_tuccar_sure.remove
On=@Logout///görev sahibi oyundan düşerse
src.SYS_KIRMIZI Görev iptal oldu.
src.events -e_tuccar_gorev
src.findid.i_tuccar_torba.remove
src.findid.i_tuccar_sure.remove