Evet arkadaşlar, bir kendi sunucunu kendin yarat projesinin kodunu sizlerle paylaşıyorum.

Öncelikle bu projenin amacı kişileri yormadan her şeyi defname üzerinden kontrol etmek. Tabi bu doğrultuda her şey deneme aşamasında olduğundan bir çok konuda fixler ve denemeler yapılıyor. Bu nedenle hani eski moongateler daha kısaydı diyenler olacaktır, daha az kısa ama daha az fix vardı bunuda unutmamak gerekiyor. Tabi bide oyuncuların her buton için ayrı bir özellik istediğnde ortaya çıkan 100lerce fazla satırı saymazsak.

Ben size her şeyi en kolay şekilde yapmayı sunuyorum, en kısa kodlamayı değil.

Bende size On=1 go britain yazıp verebilirdim ama bu bir başarı değil. Bu projenin amacı bana değil, sizlere kolay gelecek şekilde kodlamalar yapmak. Yakında çıkaracak olduğum fix paketi ile bu ve bunun gibi bir çok projeninde sahibi olabileceksiniz. Tabi isteğe göre arşivleyebilirsinizde veya istemeyebilirsinizde.

Şimdi gelelim kodumuza; Kurulumu defname altında anlatacağım;

Defname;

moongate_gototown=0 //Bu eğer 1 ise moongate lere değil şehirlere gider.

moongate_useguild=1 //Moongatelerden guilde geçiş olsun mu? (1=Evet 0=Hayır)

moongate_usestaffplaces=1 //Staff alanları olsun mu?

moongate_staffplaces=star_chamber,green_acres_3 4

moongate_regions=britain,moonglow,minoc_vesper,trinsic,skara_brae,yew,jhelom,magincia

moongate_towns=britain,moonglow,minoc,vesper,trinsic,skarabrae,yew,jhelom,magincia //Regionlar (a_townİsim_1) formatında olmalıdır.

Şimdi sizlere öncelikle defname kullanmayı öğretmek istiyorum çünkü bütün ayarlar dialogdan değil! buradan yapılıyor.

moongate_gototown=0|1 -> Buraya 1 yazarsanız moongatelere değil şehir merkezlerine gider.

moongate_useguild=0|1 -> Burada 1 yazarsanız eğer oyuncular moongate'e gittiklerinde moongate'e otomatik olarak Guild eklenir ve kullanıcı oradan guildine gidebilir. (Guildi olmayan kişilerde seçenek görünmez ve dialog ona göre uzar veya kısalır)

moongate_usestaffplaces=0|1 -> Buraya 1 yazarsanız stafflara moongate de staff alanları açılır. (Oyuncularda görünmez, dialog uzunluğunu ve kısalığını belirler.)

moongate_staffplaces=area plevel -> Buraya yazdığınız arealar, map dosyalarında a_areaadı_1 şeklinde olmaıdır. Mesela buraya star_chamber yaptığımızda map dosyasında "a_star_chamber_1" olarak geçiyor olması gerekir. Plevel kısımıda plevel limitidir. Yani 5 yazarsanız moongateden 5 plevel altında olanlar geçemez.

moongate_regions=area 0|1|2|3 Event -> Bu son moongatein en önemli özelliklerinden biri. Burası direk moongate'e geçiş olduğu için areaların map dosyalarında a_areaismi_moongate_1 şeklinde geçmesi gerekir. Boşluktan sonraki 0,1,2 ve 3 ise kişi özelliklerini belirtir. 0 (Event kullanmayacaksanız yazmanız gerekmez.) tüm oyuncuların geçebildiğini gösterir. 1, sadece pklar geçebilir, 2 sadece maviler geçebilir, 3 ise sadece criminal olanlar geçebilir. (usegotown seçeneği 1 olduğunda bu özellik kullanılmaz.)

moongate_towns=area 0|1|2|3 Event -> Buda üstteki ile aynı işlevi yapar fakat şehir isimleri girileceği için map dosyalarında a_townŞEHİRADI_1 şeklinde kayıtlı olmalıdır. Diğer tüm özellikleri üstteki ile aynıdır. (çalışması için usegotown seçeneği 1 olmalıdır.)

Moongate;

[Itemdef i_moongate]

Defname=i_moongate_v7

ID=i_moongate_red

Name=moongate



On=@Dclick

if (<distance> < 3) && (<canseelos>)

sdialog d_moongate_v7

else

src.sysmessage You can't reach that.

endif

Dialog;

[Dialog d_moongate_v7]

0,0

nomove

PAGE 1

LOCAL.TBN=<eval (<f_moonsep 0,<qval <ddef.moongate_gototown>?<def.moongate_towns>:<def.moongate_regions>>> * 20) + 90>

if (<ddef.moongate_useguild>) && (<src.memoryfindtype.memory_guild>)

LOCAL.TBN +=40

	if (<ddef.moongate_usestaffplaces>) && (<dsrc.account.plevel> > 1)

	LOCAL.TBN +=20

	endif

elif (<ddef.moongate_usestaffplaces>) && (<dsrc.account.plevel> > 1)

LOCAL.TBN +=40

endif

TBH 50,50,200,<DLOCAL.TBN>,<serv.servname> Moongate



obj = <src.memoryfindtype.memory_guild.link.uid>

LOCAL.TBG=<f_moonsep 0,<qval <ddef.moongate_gototown>?<def.moongate_towns>:<def.moongate_regions>>>

if (<ddef.moongate_useguild>) && (<src.memoryfindtype.memory_guild>)

button 70 <EVAL (<DLOCAL.TBG>*20)+140> 55 56 1 0 100

dhtmlgump 88 <EVAL (<DLOCAL.TBG>*20)+140> 124 20 0 0 <obj.name>

	if (<ddef.moongate_usestaffplaces>) && (<dsrc.account.plevel> > 1)

	Button 70 <EVAL (<DLOCAL.TBG>*20)+160> 55 56 0 2

	dhtmlgump 88 <EVAL (<DLOCAL.TBG>*20)+160> 124 20 0 0 Staff Places

	endif

elif (<ddef.moongate_usestaffplaces>) && (<dsrc.account.plevel> > 1)

button 70 <EVAL (<DLOCAL.TBG>*20)+140> 55 56 0 2

dhtmlgump 88 <EVAL (<DLOCAL.TBG>*20)+140> 124 20 0 0 Staff Places

endif



For 1 <f_moonsep 0,<qval <ddef.moongate_gototown>?<def.moongate_towns>:<def.moongate_regions>>>

	if !<ddef.moongate_gototown>

	dhtmlgump 88 <EVAL (<DLOCAL._FOR>*20)+100> 124 20 0 0 <strreverse <strsub 9 30 <strreverse <serv.area.a_<strarg <f_moonsep <DLOCAL._FOR>,<def.moongate_regions>>>_moongate_1.name>>>>

	else

	dhtmlgump 88 <EVAL (<DLOCAL._FOR>*20)+100> 124 20 0 0 <serv.area.a_town<strarg <f_moonsep <DLOCAL._FOR>,<def.moongate_towns>>>.name>

	endif

Button 70 <EVAL (<DLOCAL._FOR>*20)+100> 55 56 1 0 <DLOCAL._FOR>

Endfor



PAGE 2

TBH 50,50,200,<eval (<f_moonsep 0,<def.moongate_staffplaces>>*20)+90>,<serv.servname> Staff Places



For 1 <f_moonsep 0,<def.moongate_staffplaces>>

dhtmlgump 88 <EVAL (<DLOCAL._FOR>*20)+100> 124 20 0 0 <serv.area.a_<strarg <f_moonsep <DLOCAL._FOR>,<def.moongate_staffplaces>>>_1.name>

button 70 <EVAL (<DLOCAL._FOR>*20)+100> 55 56 1 0 <eval 200+<DLOCAL._FOR>>

Endfor



[Dialog d_moongate_v7 BUTTON]

ON=1 90

LOCAL.MOONEVENT=<streat <streat <f_moonsep <dargn>,<qval <ddef.moongate_gototown>?<DEF.moongate_towns>:<DEF.moongate_regions>>>>>

if (<distance> > 2) || !(<canseelos>)

src.sysmessage You can't reach that.

elif (<src.flags>&statf_poisoned)

src.fix Üzerinizde zehir varken bunu kullanamazsınız.

elif (<src.hits> < <src.maxhits>) //MHITS özelliği.

src.fix Yaralıyken bunu kullanamazsınız.

elif (<eval <strarg <streat <f_moonsep <dargn>,<qval <ddef.moongate_gototown>?<DEF.moongate_towns>:<DEF.moongate_regions>>>>>> == 1) && !(<src.ismurderer>) && (<dsrc.account.plevel> < 2)

src.fix Buraya maviler giremez.

elif (<eval <strarg <streat <f_moonsep <dargn>,<qval <ddef.moongate_gototown>?<DEF.moongate_towns>:<DEF.moongate_regions>>>>>> == 2) && (<src.ismurderer>) && (<dsrc.account.plevel> < 2)

src.fix Buraya pklar giremez.

elif (<eval <strarg <streat <f_moonsep <dargn>,<qval <ddef.moongate_gototown>?<DEF.moongate_towns>:<DEF.moongate_regions>>>>>> == 3) && !(<src.iscriminal>) && (<dsrc.account.plevel> < 2)

src.fix Buraya maviler ve pklar giremez.

elif (<dsrc.isevent.<LOCAL.MOONEVENT>>)

src.fix Buraya girmeye yetkiniz yok.

elif (<src.action> == id(skill_magery)) || (<src.action> == skill_magery)

src.skill fail

src.fix Büyü kullanırken buradan geçemezsiniz. //Hadi şimdide geç gatetende markla (:

elif !(strmatch('<src.region.name>', '<qval <ddef.moongate_gototown>?<serv.area.a_town<strarg <f_moonsep <DARGN>,<DEF.moongate_towns>>>.name>:<serv.area.a_<strarg <f_moonsep <DARGN>,<DEF.moongate_regions>>>_moongate_1.name>>'))

src.go <qval <ddef.moongate_gototown>?<serv.area.a_town<strarg <f_moonsep <DARGN>,<DEF.moongate_towns>>>.p>:<serv.area.a_<strarg <f_moonsep <DARGN>,<DEF.moongate_regions>>>_moongate_1.p>>

endif

return 1



On=100

if <distance> > 2

src.sysmessage You can't reach that.

elif (<src.action> == id(skill_magery)) || (<src.action> == skill_magery)

src.skill fail

else

src.go <src.memoryfindtype.memory_guild.link.p>

endif

return 1



On=200 250

if <distance> > 2

src.sysmessage You can't reach that.

elif <dsrc.account.plevel> < <streat <f_moonsep <eval <dargn>-200>,<def.moongate_staffplaces>>>

src.fix Buraya girmeye yetkiniz yok.

elif (<src.action> == id(skill_magery)) || (<src.action> == skill_magery)

src.skill fail

else

src.go <serv.area.a_<f_moonsep <eval <dargn>-200>,<def.moongate_staffplaces>>_1.p>

src.f_fizzle

endif

return 1

Gerekli functionlar;

[Function TBH]

resizepic <argv[0]> <argv[1]> 5054 <argv[2]> <eval <argv[3]>+20>

resizepic <eval <argv[0]>+10> <eval <argv[1]>+10> 3000 <eval <argv[2]>-20> <argv[3]>

dhtmlgump <eval <argv[0]>+10> <eval <argv[1]> + <argv[3]> - 15> <eval <argv[2]> - 20> 20 0 0 <def.center><def.bfont_blue><serv.url>

dhtmlgump <eval <argv[0]>+25> <eval <argv[1]>+25> <eval <argv[2]>-50> 20 0 0 <def.center><def.bfont_red><argv[4]>



[function f_moonsep]

if <argv[0]> == 0

return <eval <argv> - 1>

else

return <argv[<argv[0]>]>

endif

Deneyenler eğer hata bulurlarsa buradan yazarlarsa sevinirim.

Yarına kadar deneyenlerden veya eksik görenlerle fikir alışverişi yapacağım, bu nedenle scripti scriptler arasında yarın atacağım eğer bugün bir eksik veya hata bulunursa yazarsanız sevinirim.

şu ilk kelimen çok tuhaf özellikle içindeki kelime şimdiden özür diliyorum direk ilgimi çekti

diyorsun ki ;
"Evet arkadaşlar, bir kendi sunucunu kendin **** kodunu sizlerle paylaşıyorum."

//uyarı +1
//afronola

Bende özür diliyorum kusura bakmayın yemek yerken bir yandan kardeşimle konuşurken bu yazıyı yazdığım için harf hatası olmuş.

Özür dilerim herkesten düzelttim, new sanada ayrıca teşekkür ederim

Tebrikler güzel kodlamalar ancak moongate için bu kadar özene gerek olduğunu düşünmüyorum açıkçası.Yine de tebrik ederim bu arada yazdığın scriptlere bir önizleme resmi koyarsan benim gibi UO'ya sürekli girmeyen kişilerin daha fazlasının dikkatini çeker gibi geliyor.

Peki kardeşim seni mi kırıcam

Bu arada sorduğun için söyleyim, bu kadar fix önemli neden dersen, sunucuların sorunlarının çoğunda sorun moongatedeki buglar yüzünden çıkıyor.

xwerswoodx :
Peki kardeşim seni mi kırıcam

Bu arada sorduğun için söyleyim, bu kadar fix önemli neden dersen, sunucuların sorunlarının çoğunda sorun moongatedeki buglar yüzünden çıkıyor.

Fix'inle ilgili sıkıntı yok yahu sonuna kadar kullan.Ama dialog kısmı yaklaşık 40+ satır tutmuş.dtext ve button ile yapsaydın ancak bu kadar olabilirdi zaten.Defname ihtiyacında ortadan kalkardı boşuna for döngüsü yaparak client cpu kullanma oranını anlıkta olsa yükseltmezdin.

Bu arada dialog açılır açılmaz 5-10 saniye içinde otomatik olarak kapanma olayını ekleyebilirsin.

Mortal :

xwerswoodx :
Peki kardeşim seni mi kırıcam

Bu arada sorduğun için söyleyim, bu kadar fix önemli neden dersen, sunucuların sorunlarının çoğunda sorun moongatedeki buglar yüzünden çıkıyor.

Fix'inle ilgili sıkıntı yok yahu sonuna kadar kullan.Ama dialog kısmı yaklaşık 40+ satır tutmuş.dtext ve button ile yapsaydın ancak bu kadar olabilirdi zaten.Defname ihtiyacında ortadan kalkardı boşuna for döngüsü yaparak client cpu kullanma oranını anlıkta olsa yükseltmezdin.

Bu arada dialog açılır açılmaz 5-10 saniye içinde otomatik olarak kapanma olayını ekleyebilirsin.

Evet uzunluk konusunda katılıyorum sana ama şöyle düşün dtext ile button u defnameden kontrol edemezsin kendine eklemen ve dialog uzunluğunuda ayarlaman gerekir ayrıca onda staff ve guild butonlarını gizlersen dialog uzunluğu gereğinden fazla gözükür buda göz kirliliği demek.

Ama yinede tabiki denemede olan bir sürüm olduğunu başta belirtmiştim tabiki fixdeki sürümü bundan daha iyi olacaktır.

Hmm defname kalırdı o zaman dtext yerine eklerdin defnameli şeklinde oradan değiştirilebililirdi.Göz kirliliği konusu kişisel görüştür ona bir şey diyemem =)

tek bir kişide sıkıntı yaratmazda fazlasını hesaba katmak her zaman faydalı ilerde bir kaç saniyelik donmalar yaratabilme şansı yüksek

@xwers
başarılar dostum

artık şu oyun için bu kadar uğraşma yahu türkiyede 600 oyuncusu falan kaldı dot kapandığı zaman 400-450 lere daha sonraki yıllık süreçlerde ise türkiyede uo biticek görüşüme göre platformlarda bile takipçi bir elin parmağını geçmiyor şurdaki hevsesini global programlama dillerinde kullansan çok işine yarayabilirdi senin tercihindir gerçi gene scripte gelicek olursak gayet güzel görselliği katmazsak kodlama olarak daha ileri seviyesi olamaz.