Renk Dialogu - UO-Developer.COM

xwerswoodx

Elder Sphere Destek

Skill Title: Elder

Toplam Mesaj: 1861

Oyun Tarzı: Rp

Emulatör: Sphere

Tecrübe: Scripter

Favori Server: Second Age

Beğeni: 341 / 177

Bu dialog sayesinde Hues.mul dosyanızda bulunan renklerin hepsini görebilirsiniz. Başlangıç noktasını renk numarasını ör: 1153 yada rengin direkt hex numrasını ör: 0481 yazarak belirleyebilirsiniz.

[Function COLORS]

IF (<ISEMPTY <TAG.LSEARCH.ITEM>>)

  TAG.LSEARCH.ITEM=01415

ENDIF

DIALOG d_colors,1

[DIALOG d_colors]

50,50

NOMOVE



PAGE 1

RESIZEPIC 0 0 5120 250 150

RESIZEPIC 10 10 0bb8 230 130



RESIZEPIC 20 20 0bb8 210 30

DHTMLGUMP 25 28 150 20 0 0 Başlangıç Noktası:

RESIZEPIC 165 25 0bb8 60 20

DTEXTENTRYLIMITED 170 25 50 20 0 1 4



RESIZEPIC 20 60 0bb8 210 30

DHTMLGUMP 25 68 50 20 0 0 Item ID:

RESIZEPIC 75 65 0bb8 150 20

DTEXTENTRY 80 65 140 20 0 2 <QVAL !<ISEMPTY <SRC.TAG.LSEARCH.ITEM>>?<SERV.ITEMDEF.<SRC.TAG.LSEARCH.ITEM>.BASEID>>



RESIZEPIC 20 100 0bb8 210 30

BUTTON 205 107 025E6 025E7 1 0 1

DHTMLGUMP 25 108 180 20 0 0 Renklere Bak



PAGE 2

RESIZEPIC 0 0 5120 620 380

RESIZEPIC 10 10 0bb8 600 360



LOCAL.SCOLOR=<DARGV[0]>

IF (<DLOCAL.SCOLOR> <= 0)

  LOCAL.SCOLOR=0

ENDIF

LOCAL.OSCOLOR=<DLOCAL.SCOLOR>

LOCAL.ITEM=01415

IF !(<ISEMPTY <ARGV[1]>>)

  LOCAL.ITEM=<ARGV[1]>

ENDIF

LOCAL.ECOLOR=3000

TAG.LITEM=<LOCAL.ITEM>



FOR 0 10

  LOCAL.CLR=<EVAL <DLOCAL.SCOLOR> + <DLOCAL._FOR>>

  IF (<DLOCAL.CLR> <= <DLOCAL.ECOLOR>)

    RESIZEPIC <EVAL 20 + (<DLOCAL._FOR> * 53)> 20 0bb8 50 50

    TILEPICHUE <EVAL 25 + (<DLOCAL._FOR> * 53)> 25 <LOCAL.ITEM> <QVAL !(<DLOCAL.CLR>)?3000:<DLOCAL.CLR>>

    BUTTON <EVAL  25 + (<DLOCAL._FOR> * 53)> 74 2103 2104 1 0 <EVAL 100 + <DLOCAL.CLR>>

    DHTMLGUMP <EVAL  40 + (<DLOCAL._FOR> * 53)> 70 40 20 0 0 <HVAL <LOCAL.CLR> + 1>

  ENDIF

ENDFOR

LOCAL.SCOLOR +=11

FOR 0 10

  LOCAL.CLR=<EVAL <DLOCAL.SCOLOR> + <DLOCAL._FOR>>

  IF (<DLOCAL.CLR> <= <DLOCAL.ECOLOR>)

  RESIZEPIC <EVAL 20 + (<DLOCAL._FOR> * 53)> 100 0bb8 50 50

  TILEPICHUE <EVAL 25 + (<DLOCAL._FOR> * 53)> 105 <LOCAL.ITEM> <DLOCAL.CLR>

  BUTTON <EVAL  25 + (<DLOCAL._FOR> * 53)> 154 2103 2104 1 0 <EVAL 100 + <DLOCAL.CLR>>

  DHTMLGUMP <EVAL  40 + (<DLOCAL._FOR> * 53)> 150 40 20 0 0 <HVAL <DLOCAL.CLR> + 1>

  ENDIF

ENDFOR

LOCAL.SCOLOR +=11

FOR 0 10

  LOCAL.CLR=<EVAL <DLOCAL.SCOLOR> + <DLOCAL._FOR>>

  IF (<DLOCAL.CLR> <= <DLOCAL.ECOLOR>)

    RESIZEPIC <EVAL 20 + (<DLOCAL._FOR> * 53)> 180 0bb8 50 50

    TILEPICHUE <EVAL 25 + (<DLOCAL._FOR> * 53)> 185 <LOCAL.ITEM> <DLOCAL.CLR>

    BUTTON <EVAL  25 + (<DLOCAL._FOR> * 53)> 234 2103 2104 1 0 <EVAL 100 + <DLOCAL.CLR>>

    DHTMLGUMP <EVAL  40 + (<DLOCAL._FOR> * 53)> 230 40 20 0 0 <HVAL <DLOCAL.CLR> + 1>

  ENDIF

ENDFOR

LOCAL.SCOLOR +=11

FOR 0 10

  LOCAL.CLR=<EVAL <DLOCAL.SCOLOR> + <DLOCAL._FOR>> 

  IF (<DLOCAL.CLR> <= <DLOCAL.ECOLOR>)

    RESIZEPIC <EVAL 20 + (<DLOCAL._FOR> * 53)> 260 0bb8 50 50

    TILEPICHUE <EVAL 25 + (<DLOCAL._FOR> * 53)> 265 <LOCAL.ITEM> <DLOCAL.CLR> //<CTAG.COLOR>

    BUTTON <EVAL  25 + (<DLOCAL._FOR> * 53)> 314 2103 2104 1 0 <EVAL 100 + <DLOCAL.CLR>>

    DHTMLGUMP <EVAL  40 + (<DLOCAL._FOR> * 53)> 310 40 20 0 0 <HVAL <DLOCAL.CLR> + 1>

  ENDIF

ENDFOR

RESIZEPIC 20 330 0bb8 580 30

RESIZEPIC 260 335 0bb8 120 20

DHTMLGUMP 265 338 110 20 0 0 <DEF.CENTER><DEF.BFONT_DRED><EVAL <DLOCAL.OSCOLOR> + 1><DEF.BFONT_BLACK>-<DEF.BFONT_DRED><EVAL <DLOCAL.OSCOLOR> + 44><DEF.BFONT_BLACK>/<DEF.BFONT_DRED><DLOCAL.ECOLOR>

BUTTON 240 337 025EA 025EB 1 0 <EVAL 5000 + <DLOCAL.OSCOLOR>>

BUTTON 380 337 025E6 025E7 1 0 <EVAL 10000 + <DLOCAL.OSCOLOR>>



[DIALOG d_colors BUTTON]

On=1

IF <DARGTXT[1]> >= 3000

  SRC.SYSMESSAGE @,,1 Başlangıç noktası 3000den yüksek olamaz.

ELSE

  LOCAL.STARTP=0

  IF (<DARGTXT[1]>)

    LOCAL.STARTP=<DARGTXT[1]>

  ENDIF

  

  LOCAL.ITEM=01415

  IF !(<ISEMPTY <ARGTXT[2]>>)

  IF (<SERV.ITEMDEF.<ARGTXT[2]>.ID>)

    LOCAL.ITEM=<SERV.ITEMDEF.<ARGTXT[2]>.ID>

  ENDIF

ENDIF

SRC.TAG.LSEARCH.ITEM=<LOCAL.ITEM>

DIALOG d_colors,2,<EVAL <LOCAL.STARTP> - 1>,<LOCAL.ITEM>



On=100 3100

LOCAL.NXT=<EVAL <DARGN> - 99>

IF (!<ISEMPTY <TAG.COLOREDITEM>>)

  SERV.NEWITEM <TAG.COLOREDITEM>,1,<SRC>

  NEW.COLOR=<DLOCAL.NXT>

  REMOVE

ELSE

  SERV.NEWITEM <TAG.LITEM>

  NEW.CONT=<SRC.FINDLAYER.layer_pack>

  NEW.COLOR=<DLOCAL.NXT>

  NEW.UPDATE

ENDIF



On=5000 9999

LOCAL.NXT=<EVAL (<DARGN> - 5000) - 44>

IF !(<DLOCAL.NXT>)

  LOCAL.NXT=0

ENDIF

DIALOG d_colors,2,<DLOCAL.NXT>,<TAG.LITEM>



On=10000 14999

LOCAL.NXT=<EVAL (<DARGN> - 10000) + 44>

IF (<DLOCAL.NXT> > 2957)

  LOCAL.NXT=2957

ENDIF

DIALOG d_colors,2,<DLOCAL.NXT>,<TAG.LITEM>

Peki bu dialogu bir itemdemde kullanmak mümkün mü?
Elbette

Örnek item:

[ITEMDEF i_deed_dye]

ID=i_deed

NAME=dye deed

TYPE=t_normal



On=@DClick

TAG.COLOREDITEM=i_dye_tub_all //Burada renk butonuna tıklanınca boyanıp verilecek item.

SDIALOG d_colors,2,0,<SERV.ITEMDEF.i_dye_tub.ID> 

//Burada;

// d_colors,2 direkt renk sayfasını açmak için

// ,0, kısmındaki 0 başlangıç noktası - 1, yani 0480 yazılırsa 0481 den başlar.

// <SERV.ITEMDEF.i_dye_tub.ID> ise dialog açılınca görünmesini istediğim eşyanın IDsi, ben burada i_dye_tub'ün görünmesini istedim.

// <SERV.ITEMDEF.i_dye_tub.ID> yerine, sunucuda .show serv.itemdef.i_dye_tub.id yazıp aldığınız cevabı yazabilirsiniz.

Dye Deed için;

[spoiler=Önemli]DİPNOT: Fikrin sahibi arkadaş aşağıdaki linkteki arkadaştır.
https://forum.spherecommunit.....-Game-Hue-Tester-Sampler

Benim yaptığım ise, text içine tek tek renkleri kayıt etmek yerine, hues.mulda bulunan 3000 rengin tamamını döngü ile çekip dialoga yazdırmaktır.

Devamını göster

Son güncelleme: xwerswoodx tarafından 04-11-2017 04:21 (8 yıl önce).

MirroR

Geçmişi olmayanın, geleceği olmaz.
Scripting Destek Discord: https://discord.gg/yXQ3m5S

RasmuS

Master UO-Dev Üyesi

Üye bilgileri

Mesaj 959

Oyun tarzı Pp

Emulatör Sphere

Tecrübe Scripter

Favori Server Quests and Legends

Beğeni 113 / 32

Skill Title: Master

Toplam Mesaj: 959

Oyun Tarzı: Pp

Emulatör: Sphere

Tecrübe: Scripter

Favori Server: Quests and Legends

Beğeni: 113 / 32

Üye bilgilerini göster

Yeni yeni itemlerin yeni yeni renklerini teker teker denemek yerine burada görmek çok güzel olmuş. Fikir için arkadaşa, kodlama için sana teşekkür ederiz.
Devamını göster

Discord : rasmustivi

#90465 06-02-2017 15:10 GMT

Nigga

Journeyman UO-Dev Üyesi

Üye bilgileri

Mesaj 183

Oyun tarzı Rp

Emulatör RunUO

Tecrübe Scripter

Favori Server Yok

Beğeni 13 / 22

Skill Title: Journeyman

Toplam Mesaj: 183

Oyun Tarzı: Rp

Emulatör: RunUO

Tecrübe: Scripter

Favori Server: Yok

Beğeni: 13 / 22

Üye bilgilerini göster

Baya iyi olmuş teşekkürler
Devamını göster

New Project - Coming Soon...

#90474 06-02-2017 22:48 GMT

xwerswoodx

Elder Sphere Destek

Skill Title: Elder

Toplam Mesaj: 1861

Oyun Tarzı: Rp

Emulatör: Sphere

Tecrübe: Scripter

Favori Server: Second Age

Beğeni: 341 / 177

Yardımcı olabildiysem ne mutlu bana;

EDİT (5x+ client kullananlar için önemli ayrıntı!)
4x clientte kodu denerken 01 rengini tanımadığı için renkler geriye doğru 1 sayı kayıyordu bu nedenle ona göre düzenleme yapmıştım, bugün 7x cliente geçtim ve renk kaymasının düzeltildiğini bu nedenle dialogdaki renklerin kaydığnı farkettim, yani 4xden üstün 5x veya üzeri client kullanıyorsanız sizde de renkler kayıyor olabilir bu nedenle eğer böyle bir sorun yaşıyorsanız, dialogu şununla değiştirmeniz yeterli olacaktır;

[DIALOG d_colors]

50,50

NOMOVE



PAGE 1

RESIZEPIC 0 0 5120 250 150

RESIZEPIC 10 10 0bb8 230 130



RESIZEPIC 20 20 0bb8 210 30

DHTMLGUMP 25 28 150 20 0 0 Başlangıç Noktası:

RESIZEPIC 165 25 0bb8 60 20

DTEXTENTRYLIMITED 170 25 50 20 0 1 4



RESIZEPIC 20 60 0bb8 210 30

DHTMLGUMP 25 68 50 20 0 0 Item ID:

RESIZEPIC 75 65 0bb8 150 20

DTEXTENTRY 80 65 140 20 0 2 <QVAL !<ISEMPTY <SRC.TAG.LSEARCH.ITEM>>?<SERV.ITEMDEF.<SRC.TAG.LSEARCH.ITEM>.BASEID>>



RESIZEPIC 20 100 0bb8 210 30

BUTTON 205 107 025E6 025E7 1 0 1

DHTMLGUMP 25 108 180 20 0 0 Renklere Bak



PAGE 2

RESIZEPIC 0 0 5120 620 380

RESIZEPIC 10 10 0bb8 600 360



LOCAL.SCOLOR=<DARGV[0]>

IF (<DLOCAL.SCOLOR> <= 0)

  LOCAL.SCOLOR=0

ENDIF

LOCAL.OSCOLOR=<DLOCAL.SCOLOR>

LOCAL.ITEM=01415

IF !(<ISEMPTY <ARGV[1]>>)

  LOCAL.ITEM=<ARGV[1]>

ENDIF

//LOCAL.ECOLOR=<DARGV[1]>

//IF !(<DLOCAL.ECOLOR>)

LOCAL.ECOLOR=3000

TAG.LITEM=<LOCAL.ITEM>

//ENDIF



FOR 0 10

  LOCAL.CLR=<EVAL <DLOCAL.SCOLOR> + <DLOCAL._FOR>>

  IF (<DLOCAL.CLR> <= <DLOCAL.ECOLOR>)

    RESIZEPIC <EVAL 20 + (<DLOCAL._FOR> * 53)> 20 0bb8 50 50

    TILEPICHUE <EVAL 25 + (<DLOCAL._FOR> * 53)> 25 <LOCAL.ITEM> <DLOCAL.CLR>

    BUTTON <EVAL  25 + (<DLOCAL._FOR> * 53)> 74 2103 2104 1 0 <EVAL 100 + <DLOCAL.CLR>>

//    DHTMLGUMP <EVAL  40 + (<DLOCAL._FOR> * 53)> 70 40 20 0 0 <HVAL <LOCAL.CLR> + 1>

    DHTMLGUMP <EVAL  40 + (<DLOCAL._FOR> * 53)> 70 40 20 0 0 <LOCAL.CLR>

  ENDIF

ENDFOR

LOCAL.SCOLOR +=11

FOR 0 10

  LOCAL.CLR=<EVAL <DLOCAL.SCOLOR> + <DLOCAL._FOR>>

  IF (<DLOCAL.CLR> <= <DLOCAL.ECOLOR>)

  RESIZEPIC <EVAL 20 + (<DLOCAL._FOR> * 53)> 100 0bb8 50 50

  TILEPICHUE <EVAL 25 + (<DLOCAL._FOR> * 53)> 105 <LOCAL.ITEM> <DLOCAL.CLR>

  BUTTON <EVAL  25 + (<DLOCAL._FOR> * 53)> 154 2103 2104 1 0 <EVAL 100 + <DLOCAL.CLR>>

  DHTMLGUMP <EVAL  40 + (<DLOCAL._FOR> * 53)> 150 40 20 0 0 <LOCAL.CLR>

  ENDIF

ENDFOR

LOCAL.SCOLOR +=11

FOR 0 10

  LOCAL.CLR=<EVAL <DLOCAL.SCOLOR> + <DLOCAL._FOR>>

  IF (<DLOCAL.CLR> <= <DLOCAL.ECOLOR>)

    RESIZEPIC <EVAL 20 + (<DLOCAL._FOR> * 53)> 180 0bb8 50 50

    TILEPICHUE <EVAL 25 + (<DLOCAL._FOR> * 53)> 185 <LOCAL.ITEM> <DLOCAL.CLR>

    BUTTON <EVAL  25 + (<DLOCAL._FOR> * 53)> 234 2103 2104 1 0 <EVAL 100 + <DLOCAL.CLR>>

    DHTMLGUMP <EVAL  40 + (<DLOCAL._FOR> * 53)> 230 40 20 0 0 <LOCAL.CLR>

  ENDIF

ENDFOR

LOCAL.SCOLOR +=11

FOR 0 10

  LOCAL.CLR=<EVAL <DLOCAL.SCOLOR> + <DLOCAL._FOR>> 

  IF (<DLOCAL.CLR> <= <DLOCAL.ECOLOR>)

    RESIZEPIC <EVAL 20 + (<DLOCAL._FOR> * 53)> 260 0bb8 50 50

    TILEPICHUE <EVAL 25 + (<DLOCAL._FOR> * 53)> 265 <LOCAL.ITEM> <DLOCAL.CLR> //<CTAG.COLOR>

    BUTTON <EVAL  25 + (<DLOCAL._FOR> * 53)> 314 2103 2104 1 0 <EVAL 100 + <DLOCAL.CLR>>

    DHTMLGUMP <EVAL  40 + (<DLOCAL._FOR> * 53)> 310 40 20 0 0 <LOCAL.CLR>

  ENDIF

ENDFOR

RESIZEPIC 20 330 0bb8 580 30

RESIZEPIC 260 335 0bb8 120 20

DHTMLGUMP 265 338 110 20 0 0 <DEF.CENTER><DEF.BFONT_DRED><DLOCAL.OSCOLOR><DEF.BFONT_BLACK>-<DEF.BFONT_DRED><EVAL <DLOCAL.OSCOLOR> + 43><DEF.BFONT_BLACK>/<DEF.BFONT_DRED><DLOCAL.ECOLOR>

BUTTON 240 337 025EA 025EB 1 0 <EVAL 5000 + <DLOCAL.OSCOLOR>>

BUTTON 380 337 025E6 025E7 1 0 <EVAL 10000 + <DLOCAL.OSCOLOR>>



[DIALOG d_colors BUTTON]

On=1

IF <DARGTXT[1]> >= 3000

  SRC.SYSMESSAGE @,,1 Başlangıç noktası 3000den yüksek olamaz.

ELSE

  LOCAL.STARTP=0

  IF (<DARGTXT[1]>)

    LOCAL.STARTP=<DARGTXT[1]>

  ENDIF

  

  LOCAL.ITEM=01415

  IF !(<ISEMPTY <ARGTXT[2]>>)

  IF (<SERV.ITEMDEF.<ARGTXT[2]>.ID>)

    LOCAL.ITEM=<SERV.ITEMDEF.<ARGTXT[2]>.ID>

  ENDIF

ENDIF

SRC.TAG.LSEARCH.ITEM=<LOCAL.ITEM>

DIALOG d_colors,2,<DLOCAL.STARTP>,<LOCAL.ITEM>



On=100 3100

LOCAL.NXT=<EVAL <DARGN> - 100>

IF (!<ISEMPTY <TAG.COLOREDITEM>>)

  SERV.NEWITEM <TAG.COLOREDITEM>,1,<SRC>

  NEW.COLOR=<DLOCAL.NXT>

  REMOVE

ELSE

  SERV.NEWITEM <TAG.LITEM>

  NEW.CONT=<SRC.FINDLAYER.layer_pack>

  NEW.COLOR=<DLOCAL.NXT>

  NEW.UPDATE

ENDIF



On=5000 9999

LOCAL.NXT=<EVAL (<DARGN> - 5000) - 44>

IF !(<DLOCAL.NXT>)

  LOCAL.NXT=0

ENDIF

DIALOG d_colors,2,<DLOCAL.NXT>,<TAG.LITEM>



On=10000 14999

LOCAL.NXT=<EVAL (<DARGN> - 10000) + 44>

IF (<DLOCAL.NXT> > 2957)

  LOCAL.NXT=2957

ENDIF

DIALOG d_colors,2,<DLOCAL.NXT>,<TAG.LITEM>

DİPNOT: Geniş yer kaplayan (i_spear, i_door) gibi itemlerin çerçeveye sığmadığının farkındayım bunun için bir şeyler düşüneceğim

Devamını göster

Son güncelleme: xwerswoodx tarafından 04-11-2017 04:21 (8 yıl önce).

Geçmişi olmayanın, geleceği olmaz.
Scripting Destek Discord: https://discord.gg/yXQ3m5S

Royal

Novice UO-Dev Üyesi

Üye bilgileri

Mesaj 65

Oyun tarzı Rp

Emulatör Sphere

Tecrübe Scripter

Favori Server UO Alive

Beğeni 9 / 13

Skill Title: Novice

Toplam Mesaj: 65

Oyun Tarzı: Rp

Emulatör: Sphere

Tecrübe: Scripter

Favori Server: UO Alive

Beğeni: 9 / 13

Üye bilgilerini göster

Dostum harika olmus, tebrikler
Devamını göster

Just Royal

#90479 07-02-2017 11:47 GMT

xwerswoodx

Elder Sphere Destek

Üye bilgileri

Mesaj 1861

Oyun tarzı Rp

Emulatör Sphere

Tecrübe Scripter

Favori Server Second Age

Beğeni 341 / 177

Skill Title: Elder

Toplam Mesaj: 1861

Oyun Tarzı: Rp

Emulatör: Sphere

Tecrübe: Scripter

Favori Server: Second Age

Beğeni: 341 / 177

Üye bilgilerini göster

Teşekkür ederim yorumun için, kullanan olursa hataları belirtirse çözüm buluruz
Devamını göster

Geçmişi olmayanın, geleceği olmaz.
Scripting Destek Discord: https://discord.gg/yXQ3m5S

#90500 10-02-2017 01:18 GMT

nefrelius

Novice UO-Dev Üyesi

Üye bilgileri

Mesaj 92

Oyun tarzı Rp

Emulatör Sphere

Tecrübe Scripter

Favori Server Yok

Beğeni 23 / 36

Skill Title: Novice

Toplam Mesaj: 92

Oyun Tarzı: Rp

Emulatör: Sphere

Tecrübe: Scripter

Favori Server: Yok

Beğeni: 23 / 36

Üye bilgilerini göster

Ama hamit ya negüzel ben bunla insanlara hava atıodum neden hep aklına geliyor bunlar
Aynısını bende kullandıydım :P Çalışması için tilepichue destekleyen client kullanılması lazım onuda not düşelimde yarın bigün 2x ciler gelir
Devamını göster

Discord: Nefrelius#9069

#90503 10-02-2017 01:50 GMT

xwerswoodx

Elder Sphere Destek

Üye bilgileri

Mesaj 1861

Oyun tarzı Rp

Emulatör Sphere

Tecrübe Scripter

Favori Server Second Age

Beğeni 341 / 177

Skill Title: Elder

Toplam Mesaj: 1861

Oyun Tarzı: Rp

Emulatör: Sphere

Tecrübe: Scripter

Favori Server: Second Age

Beğeni: 341 / 177

Üye bilgilerini göster

Hahaha, baktım artık kimse forumla ilgilenmiyor bende biraz konu açayım dedim kim bilir belki bazı arkadaşlar örnek alırda tekrardan forum hareketlenir, yani öyle umuyorum. Tilepichue içinse ne kadar zaman geçmiş bak ben client gerektiğini bile unutmuşum, 2.0.3 kullanmayı bırakalı seneler oluyor 4x kullanıyordum 7xe geçiş yaptım Bence kanal 2xcilerde connector yapımcılarının 2x e destek vrmesinden kaynaklı bence ) Ama evet not düşelim belirttiğin gibi 3x+ mı istiyordu kaç istiyrdu aklıma bile gelmiyor yeminle )
Devamını göster

Geçmişi olmayanın, geleceği olmaz.
Scripting Destek Discord: https://discord.gg/yXQ3m5S

#90506 10-02-2017 08:18 GMT

stylez

Journeyman UO-Dev Üyesi

Üye bilgileri

Mesaj 226

Oyun tarzı Pvp

Emulatör Sphere

Tecrübe Diğer

Favori Server Tides of Power

Beğeni 25 / 13

Skill Title: Journeyman

Toplam Mesaj: 226

Oyun Tarzı: Pvp

Emulatör: Sphere

Tecrübe: Diğer

Favori Server: Tides of Power

Beğeni: 25 / 13

Üye bilgilerini göster

Eline sağlık
Devamını göster

Son güncelleme: stylez tarafından 24-12-2021 18:36 (4 yıl önce).

Ultima Online .Mul Dersleri

#97666 08-12-2019 20:50 GMT

Freeman

Apprentice UO-Dev Üyesi

Skill Title: Apprentice

Toplam Mesaj: 111

Oyun Tarzı: Rp

Emulatör: Sphere

Tecrübe: Player

Favori Server: Traditions

Beğeni: 46 / 35

Orjinalini olani dene bir de

// In-Game Hue Tester/Sampler

// By n1ghtwish/Maximus

// LAST EDITED: 9/06/2016



[DEFNAME hueTest_Settings]

htMaxPP = 15                            // max tiles per page (don't change this unless you modify the overall dialog size and other code)

htDefHuesFile = "hues.txt"                // default hues file from root Sphere directory



[FUNCTION huetest]

sdialog dHueTest



[DIALOG dHueTest]

150,150

page 0

resizepic 0 0 2620 300 220

checkertrans 5 5 290 215

dhtmlgump 15 15 269 25 1 0 <def.center><def.big>Hue Tester - Options<def.bige><def.centere>

button 15 60 4005 4007 1 0 1 // hue range

dtext 57 60 68 Range

resizepic 100 60 9350 40 23

dtextentrylimited 103 61 40 23 0 1 4 <eval rand(1,1500)>

dtext 150 61 68 TO

resizepic 180 60 9350 40 23

dtextentrylimited 183 61 40 23 0 2 4 <eval rand(1501,3000)>

button 15 90 4005 4007 1 0 2 // file

dtext 57 90 68 File

resizepic 100 90 9350 180 23

dtextentrylimited 103 90 180 23 0 3 30 <def.htDefHuesFile>

button 15 120 4005 4007 1 0 3 // all 3,000

dtext 57 120 68 ALL Hues

button 15 180 4017 4019 1 0 0 // close

dtext 57 180 68 Close



[DIALOG dHueTest BUTTON]

ON=0 // cancel

sysmessage Aborted!



ON=1 // range

if (<isempty <argtxt1>>)||(<isempty <argtxt2>>)||(!<isnum <argtxt1>>)||(!<isnum <argtxt2>>)

    sysmessage Must provide two numbers for hue range!

    return 1

elseif (<isnum <argtxt1>>)&&(<isnum <argtxt2>>)&&(<argtxt1> > <argtxt2>)

    sysmessage Invalid range.

    return 1

endif

ctag.htType = 1

ctag.htB = <argtxt1>

ctag.htE = <argtxt2>

sysmessage Select target.

targetf fHuetest



ON=2 // file

if (!<FILE.FILEEXIST <argtxt3>>)

    sysmessage File "<argtxt3>" not found!

    return 1

endif

ctag.htType = 2

ctag.htFile = <argtxt3>

sysmessage Select target.

targetf fHuetest



ON=3 // all

ctag.htType = 3

sysmessage Select target.

targetf fHuetest



[FUNCTION fHuetest]

// You could get rid of this IF statement to allow targeting of characters as well

if (<argo.isitem>)

    ctag.htTileBG = 2620

    ctag.htPnum = 1

    argo.sdialog dHuetest2

    return 1

endif

sysmessage Items only, dummy!



[DIALOG dHuetest2]

100,100

page 0

resizepic 0 0 2620 700 560

checkertrans 5 5 695 555

doswitch <eval <src.ctag.htType> - 1>

    begin // range

        local.tnum = <eval <eval <src.ctag.htE> - <src.ctag.htB>> + 1>

        dhtmlgump 15 15 670 25 1 0 <def.center><def.big>Hue Tester - Range: <src.dctag.htB> to <src.dctag.htE><def.bige><def.centere>

    end

    begin // file

        FILE.MODE.WRITEFLAG = 0

        FILE.MODE.CREATEFLAG = 0

        FILE.MODE.READFLAG = 1

        if (<FILE.OPEN <src.ctag.htFile>>)

            local.tnum = <FILE.FILELINES <src.ctag.htFile>>

        endif

        dhtmlgump 15 15 670 25 1 0 <def.center><def.big>Hue Tester - File: <src.ctag.htFile> - <dlocal.tnum> hues<def.bige><def.centere>

    end

    begin // all

        local.tnum = 3000

        dhtmlgump 15 15 670 25 1 0 <def.center><def.big>Hue Tester - ALL HUES<def.bige><def.centere>

    end        

enddo

local.pages = <eval (((<local.tnum> - 1) / <def.htMaxPP>) + 1)>

if (<src.ctag.htPnum> > <local.pages>)

    src.ctag.htPnum = <dlocal.pages>

endif

local.offset = <qval (<src.ctag.htPnum> > 1) ? <eval ((<src.ctag.htPnum> - 1) * <def.htMaxPP>)> : 1>

local.x = 15

local.y = 45

if (<local.tnum> >= 1)

    for h <dlocal.offset> <eval <local.offset> + <eval <def.htMaxPP> - 1>>

        if (<local.h> <= <local.tnum>)

            local.c += 1

            resizepic <dlocal.x> <dlocal.y> <eval <src.ctag.htTileBG>> 126 126 // 2620 dark, 3000 light

            doswitch <eval <src.ctag.htType> - 1>

                begin // range

                    tilepichue <eval <local.x> + 45> <eval <local.y> + 15> <id> <eval <eval <local.h> + <src.ctag.htB>> - 1>

                    button <eval <local.x> + 46> <eval <local.y> + 135> 2103 2104 1 0 <eval <eval <local.h> + <src.ctag.htB> - 1> + 3>

                    dtext <eval <local.x> + 60> <eval <local.y> + 130> 1152 <eval <eval <local.h> + <src.ctag.htB>> - 1>

                end

                begin // file

                    tilepichue <eval <local.x> + 45> <eval <local.y> + 15> <id> <FILE.READLINE <dlocal.h>>

                    button <eval <local.x> + 46> <eval <local.y> + 135> 2103 2104 1 0 <eval <FILE.READLINE <dlocal.h>> + 3>

                    dtext <eval <local.x> + 60> <eval <local.y> + 130> 1152 <FILE.READLINE <dlocal.h>>

                end

                begin // all

                    tilepichue <eval <local.x> + 45> <eval <local.y> + 15> <id> <dlocal.h>

                    button <eval <local.x> + 46> <eval <local.y> + 135> 2103 2104 1 0 <eval <local.h> + 3>

                    dtext <eval <local.x> + 60> <eval <local.y> + 130> 1152 <dlocal.h>

                end

            enddo

            local.x += 135

            if (<local.c> == 5)

                local.x = 15

                local.y = 200

            elseif (<local.c> == 10)

                local.x = 15

                local.y = 360

            endif

        endif

    end

endif

FILE.CLOSE

button 15 517 4005 4007 1 0 3

dtext 50 517 1152 Toggle Light/Dark BG

if (<src.ctag.htPnum> > 1)

    button 275 520 9909 9909 1 0 1

endif

dhtmlgump 305 517 100 25 1 0 <def.center><eval <src.ctag.htPnum>> / <dlocal.pages><def.centere>

if (<local.pages> > <src.ctag.htPnum>)

    button 414 519 9903 9903 1 0 2

endif



[DIALOG dHuetest2 BUTTON]

ON=1 2

doswitch <eval <argn1> - 1>

    src.ctag.htPnum -= 1

    src.ctag.htPnum += 1

end

sdialog dHuetest2



ON=3

src.ctag.htTileBG = <qval <src.ctag.htTileBG> == 2620 ? 3000:2620>

sdialog dHuetest2



ON=4 3100

color = <eval <argn1> - 3>

Devamını göster

Geceleri uyuyamayanların, gündüzlere sığamayacak kadar karmaşık hesapları vardır.

BENZER BAŞLIKLAR

Konu	Kategori	Son cevap	Son yazan	Mesaj	Görüntüleme
Renk sorunu Son cevap: 26-05 20:37 · Son yazan: mahsuni · Mesaj: 11 · Görüntü: 4885	Script Yardımı	26-05 20:37	mahsuni	11	4885
Binek renk sorunu Son cevap: 04-05 08:06 · Son yazan: senedor250 · Mesaj: 9 · Görüntü: 4261	Script Yardımı	04-05 08:06	senedor250	9	4261
Player isim /RENK Son cevap: 18-10 16:35 · Son yazan: Pidra · Mesaj: 10 · Görüntü: 4882	Script Yardımı	18-10 16:35	Pidra	10	4882
tilepichue Renk Son cevap: 05-02 05:44 · Son yazan: MirroR · Mesaj: 4 · Görüntü: 4435	Script Yardımı	05-02 05:44	MirroR	4	4435
Renk ekleme Son cevap: 10-12 15:52 · Son yazan: Silverwolf · Mesaj: 1 · Görüntü: 2673	Muls ve Mul Editing	10-12 15:52	Silverwolf	1	2673

Sosyal Ağ ile Giriş Yap

Google ile Bağlan Facebook ile Bağlan Twitch ile Bağlan Discord ile Bağlan

BENZER BAŞLIKLAR

Sosyal Ağ ile Giriş Yap

Çerez Tercihleri